Clipper On Line • Ver Tópico - Dúvida urgente sobre comando GRID

Dúvida urgente sobre comando GRID

Projeto MiniGui - Biblioteca visual para Harbour/xHarbour

Moderador: Moderadores

 

Dúvida urgente sobre comando GRID

Mensagempor Paulo_CPV » 08 Nov 2013 07:32

Bom dia!

Estou aqui num dilema danado, estou utilizando Minigui Extend 2.2.8. Tenho uma tela de pesquisa que tem LABEL's e uma GRID com no minimo de 1.000 registros. Estou com dúvida como eu faço para que quando eu movimentar (seta para cima ou para baixo) pela GRID apareçam os dados nos LABEL's correspondentes, já fiz de tudo e não estou conseguindo se alguém tiver uma idéia de como eu faço isto ficarei grato. Estou com uma certa urgencia para acertar isso.

[]'s
Paulo - Jacareí/SP
Paulo_CPV
Usuário Nível 3

Usuário Nível 3
 
Mensagens: 178
Data de registro: 07 Mar 2013 10:27
Cidade/Estado: Jacarei/SP
Curtiu: 0 vez
Mens.Curtidas: 1 vez

Dúvida urgente sobre comando GRID

Mensagempor Pablo César » 08 Nov 2013 09:11

Olá Paulo, o Grid possui uma propriedade chamada ON CHANGE onde você irá colocar uma função que lê o atual registro e nessa mesma função você pode atribuir tais valores ao LABEL.
Um clip-abraço !

Pablo César Arrascaeta
Compartilhe suas dúvidas e soluções com todos os colegas aqui do fórum.
Evite enviar as dúvidas técnicas por MPs ou eMails, assim todos iremos beneficiar-nos.
Avatar de usuário

Pablo César
Usuário Nível 7

Usuário Nível 7
 
Mensagens: 5312
Data de registro: 31 Mai 2006 10:22
Cidade/Estado: Curitiba - Paraná
Curtiu: 142 vezes
Mens.Curtidas: 152 vezes

Dúvida urgente sobre comando GRID

Mensagempor Paulo_CPV » 08 Nov 2013 09:22

Bom dia, Pablo!

Obrigado pela sua atenção, isto eu já fiz e não está dando certo. Você teria como me passar um exemplo de como eu tenho que proceder para solucionar este problema, pois no comando Browse funciona certinho, pois estou migrando para o comando Grid e estou ficando maluquinho com este comando por que só utilizava o comando Browse.

[]'s
Paulo - Jacareí/SP
Paulo_CPV
Usuário Nível 3

Usuário Nível 3
 
Mensagens: 178
Data de registro: 07 Mar 2013 10:27
Cidade/Estado: Jacarei/SP
Curtiu: 0 vez
Mens.Curtidas: 1 vez

Dúvida urgente sobre comando GRID

Mensagempor Pablo César » 08 Nov 2013 09:28

Ai que está Paulo, só posso trabalhar encima do que você tentou.
Tem várias formas de utilizar o Grid. Mostra o seu código ou parte dele que eu possa compilar. Mas basicamente é como eu te disse, faça uma função que leia o atual registro que está posicionado no Grid.
Um clip-abraço !

Pablo César Arrascaeta
Compartilhe suas dúvidas e soluções com todos os colegas aqui do fórum.
Evite enviar as dúvidas técnicas por MPs ou eMails, assim todos iremos beneficiar-nos.
Avatar de usuário

Pablo César
Usuário Nível 7

Usuário Nível 7
 
Mensagens: 5312
Data de registro: 31 Mai 2006 10:22
Cidade/Estado: Curitiba - Paraná
Curtiu: 142 vezes
Mens.Curtidas: 152 vezes

Dúvida urgente sobre comando GRID

Mensagempor Toledo » 08 Nov 2013 09:50

Amigos, segue em anexo um pequeno exemplo.

Abraços,
Anexos
grid.zip
(638.5 KiB) Baixado 133 vezes
Toledo - Clipper On Line
toledo@pctoledo.com.br
Harbour 3.2/MiniGui/HwGui
Faça uma doação para o fórum, clique neste link: http://www.pctoledo.com.br/doacao
Avatar de usuário

Toledo
Administrador

Administrador
 
Mensagens: 3038
Data de registro: 22 Jul 2003 18:39
Cidade/Estado: Araçatuba - SP
Curtiu: 263 vezes
Mens.Curtidas: 258 vezes

Dúvida urgente sobre comando GRID

Mensagempor Paulo_CPV » 08 Nov 2013 14:59

Boa tarde!

Pablo, Toledo fiz as alterações do exemplo que o amigo Toledo anexou e não deu certo ainda.

Eu vou extrair parte do meu sistema e anexo aqui para vocês poderem me ajudar a resolver este problema. Desde já agradeço a atenção de vocês.

[]'s
Paulo - Jacareí/SP
Paulo_CPV
Usuário Nível 3

Usuário Nível 3
 
Mensagens: 178
Data de registro: 07 Mar 2013 10:27
Cidade/Estado: Jacarei/SP
Curtiu: 0 vez
Mens.Curtidas: 1 vez

Dúvida urgente sobre comando GRID

Mensagempor Pablo César » 08 Nov 2013 21:36

Paulo_CPV escreveu:fiz as alterações do exemplo que o amigo Toledo anexou e não deu certo ainda.

Eu vou extrair parte do meu sistema e anexo aqui para vocês poderem me ajudar a resolver este problema
Seria interessante que você anexasse as suas tentativas. As suas dúvidas e soluções apresentadas, poderão servir para outros no futuro.
Um clip-abraço !

Pablo César Arrascaeta
Compartilhe suas dúvidas e soluções com todos os colegas aqui do fórum.
Evite enviar as dúvidas técnicas por MPs ou eMails, assim todos iremos beneficiar-nos.
Avatar de usuário

Pablo César
Usuário Nível 7

Usuário Nível 7
 
Mensagens: 5312
Data de registro: 31 Mai 2006 10:22
Cidade/Estado: Curitiba - Paraná
Curtiu: 142 vezes
Mens.Curtidas: 152 vezes

Dúvida urgente sobre comando GRID

Mensagempor Paulo_CPV » 10 Nov 2013 14:19

Boa tarde a todos!

Estou enviando parte de meu sistema a onde está dando erro para que os colegas me ajudem a resolver este problema, pois até o momento não tive êxito na resolução do problema. Espero que os colegas possam me ajudar analisando o me código:

#Include "Minigui.ch"

#DEFINE FECHA_JANELA   ThisWindow.Release
#DEFINE SUAVE_1         {255,250,205}
#DEFINE BK_TEXTO3      {245,222,179}
#DEFINE PRETO         {0,0,0}
#DEFINE BRANCO         {255,255,255}
#DEFINE AZUL_006         {0,0,160}
#DEFINE W(n)         INT(n*(GetDesktopWidth() / 800 ))
#DEFINE H(n)         INT(n*(GetDesktopHeight() / 600))
#DEFINE LADIREITA       RIGHTALIGN
#DEFINE BAESQUERDA      BROWSE_JTFY_LEFT
#DEFINE BACENTRA        BROWSE_JTFY_CENTER
#DEFINE BADIREITA       BROWSE_JTFY_RIGHT
#DEFINE ORGANIZAR      {BACENTRA,BAESQUERDA,BACENTRA,BACENTRA,BACENTRA,BACENTRA,BAESQUERDA,BAESQUERDA,BACENTRA}
#DEFINE DRIVER         "DBFCDX"
**************************************************************
REQUEST HB_LANG_PT
HB_LANGSELECT("PT")

SET DATE FORMAT "dd/mm/yyyy"
SET DATE TO BRITISH
SET MULTIPLE OFF
SET CENTURY ON
SET EPOCH TO 1960
SET DELETE ON
SET DECIMAL TO 2
SET ESCAPE ON
SET SCOREBOARD OFF
SET BELL ON
SET CONSOLE OFF
SET EXCLUSIVE OFF
SET CONFIRM ON

SET BROWSESYNC ON
SET NAVIGATION EXTENDED
SET LANGUAGE TO PORTUGUESE
SET TOOLTIPBALLOON ON
SET CENTERWINDOW RELATIVE DESKTOP
SET CELLNAVIGATIONMODE VERTICAL
   
SET MENUSTYLE EXTENDED
SET MENUITEM BORDER 3D
SET MENUCURSOR SHORT
   
REQUEST DBFCDX , DBFFPT
RDDSETDEFAULT("DBFCDX")
*********************************************
      aarq :={}

      Aadd( aarq , { 'Mat_Imp'     , 'C' , 06 , 0 } )
      Aadd( aarq , { 'Nome_Imp'    , 'C' , 50 , 0 } )
      Aadd( aarq , { 'Dib_Imp'     , 'D' , 08 , 0 } )
      Aadd( aarq , { 'Sexo_Imp'    , 'C' , 01 , 0 } )
      Aadd( aarq , { 'NIT_Imp'     , 'C' , 15 , 0 } )
      Aadd( aarq , { 'CPF_Imp'     , 'C' , 14 , 0 } )
      Aadd( aarq , { 'SitPrc_Imp'  , 'C' , 60 , 0 } )
      Aadd( aarq , { 'Motivo_Imp'  , 'C' , 60 , 0 } )
      Aadd( aarq , { 'TipApo_Imp'  , 'C' , 60 , 0 } )
      Aadd( aarq , { 'Falc_Imp'    , 'C' , 01 , 0 } )
      Aadd( aarq , { 'DatFal_Imp'  , 'D' , 08 , 0 } )
      Aadd( aarq , { 'Exped'       , 'C' , 18 , 0 } )

      DBCreate( ((cArquivo)) , aarq, DRIVER   )

        USE SISCPV_IMP ALIAS SISCPVIMP NEW SHARED VIA DRIVER
      
        INDEX ON DTOS(Dib_Imp) TAG Ind1 TO  "IndcpvImp"
        INDEX ON nit_Imp       TAG Ind2 TO  "IndcpvImp"
        INDEX ON nome_imp      TAG Ind3 TO  "IndcpvImp"
        INDEX ON cpf_imp       TAG Ind4 TO  "IndcpvImp"
        INDEX ON mat_imp       TAG Ind5 TO  "IndcpvImp"
        INDEX ON SitPrc_Imp    TAG Ind6 TO  "IndcpvImp"
        INDEX ON DTOS(Dib_Imp) + SitPrc_Imp TAG Ind7 TO "IndcpvImp"
        INDEX ON DTOS(Dib_Imp) + nome_Imp   TAG Ind8 TO "IndcpvImp"      
      
        SISCPVIMP->(DBGotop())
     
         DEFINE WINDOW Janela03 ;
         AT W(83), H(1) WIDTH W(800) HEIGHT H(466) ;
         TITLE "Consulta de Servidores" ;
         ICON "" ;
         MODAL ;
         BACKCOLOR SUAVE_1 ;
         FONT "Arial" SIZE 10 ;
       ON INIT {|| EncheDadosGrid()} ;

         ON KEY ESCAPE ACTION {|| FECHA_JANELA}
         
         DEFINE SPLITBOX

            DEFINE TOOLBAR ToolBar_1 BUTTONSIZE W(80), H(48) FLAT FONT "Arial" SIZE 9 BOLD
/* Função funcionando
               BUTTON Btn_Alterar ;
               CAPTION "Alterar" ;
               TOOLTIP 'Altera um registro no Banco de Dados' ;
               ACTION {|| TelaAtualizar()}

               BUTTON Btn_Pesquisa ;
               CAPTION "Consultar" ;
               TOOLTIP 'Faz a consulta por NIT ou Nome' ;
            ACTION {|| Janela03.text_2.Setfocus}
*/
               BUTTON Btn_Volta ;
               CAPTION "Sair" ;
               TOOLTIP 'Volta para a tela principal' ;
               ACTION {|| FECHA_JANELA }

            END TOOLBAR

         END SPLITBOX

         DEFINE FRAME frame_1
     
            ROW W(66)
            COL H(5)
            WIDTH W(784)
            HEIGHT H(207)
            CAPTION "Dados do Registro"
            OPAQUE .T.
            FONTNAME "Arial"
            FONTSIZE 12
            FONTBOLD .T.
            FONTCOLOR PRETO
            BACKCOLOR SUAVE_1
     
         END FRAME

         DEFINE FRAME frame_2
     
            ROW W(84)
            COL H(14)
            WIDTH W(140)
            HEIGHT H(45)
            CAPTION "Matricula"
            OPAQUE .T.
            FONTNAME "Arial"
            FONTSIZE 9
            FONTBOLD .T.
            FONTCOLOR PRETO
            BACKCOLOR SUAVE_1
     
         END FRAME

         DEFINE FRAME frame_3
     
            ROW W(84)
            COL H(159)
            WIDTH W(622)
            HEIGHT H(45)
            CAPTION "Nome do Servidor"
            OPAQUE .T.
            FONTNAME "Arial"
            FONTSIZE 9
            FONTBOLD .T.
            FONTCOLOR PRETO
            BACKCOLOR SUAVE_1
     
         END FRAME

         DEFINE FRAME frame_4
     
            ROW W(129)
            COL H(14)
            WIDTH W(140)
            HEIGHT H(45)
            CAPTION "DIB"
            OPAQUE .T.
            FONTNAME "Arial"
            FONTSIZE 9
            FONTBOLD .T.
            FONTCOLOR PRETO
            BACKCOLOR SUAVE_1
     
         END FRAME

         DEFINE FRAME frame_5
     
            ROW W(129)
            COL H(159)
            WIDTH W(140)
            HEIGHT H(45)
            CAPTION "NIT"
            OPAQUE .T.
            FONTNAME "Arial"
            FONTSIZE 9
            FONTBOLD .T.
            FONTCOLOR PRETO
            BACKCOLOR SUAVE_1
     
         END FRAME
         
         DEFINE FRAME frame_6
     
            ROW W(129)
            COL H(304)
            WIDTH W(140)
            HEIGHT H(45)
            CAPTION "Sexo"
            OPAQUE .T.
            FONTNAME "Arial"
            FONTSIZE 9
            FONTBOLD .T.
            FONTCOLOR PRETO
            BACKCOLOR SUAVE_1
     
         END FRAME

         DEFINE FRAME frame_7
     
            ROW W(129)
            COL H(451)
            WIDTH W(140)
            HEIGHT H(45)
            CAPTION "CPF"
            OPAQUE .T.
            FONTNAME "Arial"
            FONTSIZE 9
            FONTBOLD .T.
            FONTCOLOR PRETO
            BACKCOLOR SUAVE_1
     
         END FRAME

         DEFINE FRAME frame_8
     
            ROW W(175)
            COL H(14)
            WIDTH W(330)
            HEIGHT H(45)
            CAPTION "Situação"
            OPAQUE .T.
            FONTNAME "Arial"
            FONTSIZE 9
            FONTBOLD .T.
            FONTCOLOR PRETO
            BACKCOLOR SUAVE_1
     
         END FRAME

         DEFINE FRAME frame_9
     
            ROW W(175)
            COL H(349)
            WIDTH W(430)
            HEIGHT H(45)
            CAPTION "Motivo"
            OPAQUE .T.
            FONTNAME "Arial"
            FONTSIZE 9
            FONTBOLD .T.
            FONTCOLOR PRETO
            BACKCOLOR SUAVE_1
     
         END FRAME

         DEFINE FRAME frame_10
     
            ROW W(220)
            COL H(14)
            WIDTH W(200)
            HEIGHT H(45)
            CAPTION "Tipo de Aposentadoria"
            OPAQUE .T.
            FONTNAME "Arial"
            FONTSIZE 9
            FONTBOLD .T.
            FONTCOLOR PRETO
            BACKCOLOR SUAVE_1
     
         END FRAME

         DEFINE FRAME frame_11
     
            ROW W(220)
            COL H(218)
            WIDTH W(140)
            HEIGHT H(45)
            CAPTION "Falecido"
            OPAQUE .T.
            FONTNAME "Arial"
            FONTSIZE 9
            FONTBOLD .T.
            FONTCOLOR PRETO
            BACKCOLOR SUAVE_1
     
         END FRAME

         DEFINE FRAME frame_12
     
            ROW W(220)
            COL H(363)
            WIDTH W(140)
            HEIGHT W(45)
            CAPTION "Data de Falecimento"
            OPAQUE .T.
            FONTNAME "Arial"
            FONTSIZE 9
            FONTBOLD .T.
            FONTCOLOR PRETO
            BACKCOLOR SUAVE_1
     
         END FRAME

         DEFINE FRAME frame_13
     
            ROW W(220)
            COL H(510)
            WIDTH W(140)
            HEIGHT W(45)
            CAPTION "Processo Aprovado"
            OPAQUE .T.
            FONTNAME "Arial"
            FONTSIZE 9
            FONTBOLD .T.
            FONTCOLOR PRETO
            BACKCOLOR SUAVE_1
     
         END FRAME

         DEFINE LABEL label_1
     
            ROW W(103)
            COL H(21)
            WIDTH W(120)
            HEIGHT H(24)
            FONTNAME "Arial"
            FONTSIZE 10
            FONTBOLD .T.
            FONTCOLOR PRETO
            CENTERALIGN .T.
            BACKCOLOR SUAVE_1
     
         END LABEL

         DEFINE LABEL label_2
     
            ROW W(103)
            COL H(169)
            WIDTH W(500)
            HEIGHT H(24)
            FONTNAME "Arial"
            FONTSIZE 10
            FONTBOLD .T.
            FONTCOLOR PRETO
            BACKCOLOR SUAVE_1
     
         END LABEL

         DEFINE LABEL label_3
     
            ROW W(148)
            COL H(21)
            WIDTH W(120)
            HEIGHT H(24)
            FONTNAME "Arial"
            FONTSIZE 10
            FONTBOLD .T.
            FONTCOLOR PRETO
            CENTERALIGN .T.
            BACKCOLOR SUAVE_1
     
         END LABEL

         DEFINE LABEL label_4
     
            ROW W(148)
            COL H(168)
            WIDTH W(120)
            HEIGHT H(24)
            FONTNAME "Arial"
            FONTSIZE 10
            FONTBOLD .T.
            FONTCOLOR PRETO
            CENTERALIGN .T.
            BACKCOLOR SUAVE_1
     
         END LABEL

         DEFINE LABEL label_5
     
            ROW W(148)
            COL H(314)
            WIDTH W(120)
            HEIGHT H(24)
            FONTNAME "Arial"
            FONTSIZE 10
            FONTBOLD .T.
            FONTCOLOR PRETO
            CENTERALIGN .T.
            BACKCOLOR SUAVE_1
     
         END LABEL
     
         DEFINE LABEL label_6
     
            ROW W(148)
            COL H(461)
            WIDTH W(120)
            HEIGHT H(24)
            FONTNAME "Arial"
            FONTSIZE 10
            FONTBOLD .T.
            FONTCOLOR PRETO
            CENTERALIGN .T.
            BACKCOLOR SUAVE_1
     
         END LABEL

         DEFINE LABEL label_7
     
            ROW W(194)
            COL H(21)
            WIDTH W(295)
            HEIGHT H(24)
            FONTNAME "Arial"
            FONTSIZE 10
            FONTBOLD .T.
            FONTCOLOR PRETO
            BACKCOLOR SUAVE_1
     
         END LABEL

         DEFINE LABEL label_8
     
            ROW W(194)
            COL H(358)
            WIDTH W(295)
            HEIGHT H(24)
            FONTNAME "Arial"
            FONTSIZE 10
            FONTBOLD .T.
            FONTCOLOR PRETO
            BACKCOLOR SUAVE_1
     
         END LABEL

         DEFINE LABEL label_9
     
            ROW W(239)
            COL H(21)
            WIDTH W(190)
            HEIGHT H(24)
            FONTNAME "Arial"
            FONTSIZE 10
            FONTBOLD .T.
            FONTCOLOR PRETO
            BACKCOLOR SUAVE_1
     
         END LABEL

         DEFINE LABEL label_10
     
            ROW W(239)
            COL H(373)
            WIDTH W(120)
            HEIGHT H(24)
            FONTNAME "Arial"
            FONTSIZE 10
            FONTBOLD .T.
            FONTCOLOR PRETO
            CENTERALIGN .T.
            BACKCOLOR SUAVE_1
     
         END LABEL

         DEFINE CHECKBOX checkbox_1
     
            ROW W(235)
            COL H(237)
            WIDTH W(100)
            HEIGHT H(24)
            CAPTION "Sim"
            VALUE .F.
            FONTNAME "Arial"
            FONTSIZE 10
            FONTBOLD .T.
            FONTCOLOR PRETO
            BACKCOLOR SUAVE_1
     
         END CHECKBOX

         DEFINE CHECKBOX checkbox_2
     
            ROW W(235)
            COL H(522)
            WIDTH W(100)
            HEIGHT H(24)
            CAPTION "Sim"
            VALUE .F.
            FONTNAME "Arial"
            FONTSIZE 10
            FONTBOLD .T.
            FONTCOLOR PRETO
            BACKCOLOR SUAVE_1
     
         END CHECKBOX

         DEFINE LABEL label_11
     
            ROW W(407)
            COL H(3)
            WIDTH W(75)
            HEIGHT H(18)
            VALUE "Buscar por:"
            FONTNAME "Arial"
            FONTSIZE 10
            FONTBOLD .T.
            FONTCOLOR PRETO
            BACKCOLOR SUAVE_1
     
         END LABEL

         DEFINE TEXTBOX text_2
     
            ROW W(405)
            COL H(90)
            WIDTH W(500)
            HEIGHT H(24)
            VALUE ""
            FONTNAME "Arial"
            FONTSIZE 10
            FONTBOLD .T.
            FONTCOLOR PRETO
            BACKCOLOR BK_TEXTO3
            TOOLTIP "Faz consulta por [Nome] ou [NIT] Servidor"
            UPPERCASE .T.
            MAXLENGTH 40
//         ONCHANGE {|| PesqNome()}
//         ONENTER  {|| PegaNome()} Funções funcionando
     
         END TEXTBOX
      
       DEFINE GRID grid_1
      
            ROW W(277)
            COL H(3)
            WIDTH W(784)
            HEIGHT H(115)
            HEADERS {'Mat.','Nome','DIB','Sexo','NIT','CPF','Situação','Motivo','Tipo Apo.'}
            WIDTHS  {45,390,85,55,105,105,120,190,120}
            FONTNAME 'Arial'
            FONTSIZE 10
            FONTBOLD .T.
         FONTCOLOR BRANCO
         ITEMS aBuscaServ
         BACKCOLOR AZUL_006
         JUSTIFY ORGANIZAR
         CELLNAVIGATION .T.
         ONCHANGE  {||  GridAtualizaDados()} // Aqui que esta o erro
//         ONDBLCLICK {||SelNome()} -> Função funcionando

       END GRID
         
         END WINDOW
         
         GridAtualizaDados()
         
         Janela03.Activate
********************************************** Funções

FUNCTION EncheDadosGrid()

   SISCPVIMP->(DBSetOrder(1))
   SISCPVIMP->(DBGotop())

   WHILE ! SISCPVIMP->(EOF())

      Janela03.Grid_1.AddItem({siscpvimp->mat_imp,siscpvimp->nome_imp,DTOC(siscpvimp->dib_imp),siscpvimp->sexo_imp,oSistema:MascaraNit(siscpvimp->nit_imp),siscpvimp->cpf_imp,siscpvimp->sitprc_imp,siscpvimp->motivo_imp,siscpvimp->tipapo_imp} )
     
      IF SISCPVIMP->(EOF())
     
         EXIT
         
      ENDIF
     
      SISCPVIMP->(DBSKIP())
   
   END
   
RETURN NIL

****************************************** Função que esta dando erro

FUNCTION GridAtualizaDados()

   LOCAL nPos := This.CellRowIndex
   
   aRet := Janela03.Grid_1.Item(nPos)
   
   SISCPVIMP->(DBSetOrder(3))
   SISCPVIMP->(DBGotop())
   SISCPVIMP->(DBSeek(aRet[2]))
   
   IF FOUND()
   
   Janela03.label_1.Value    := siscpvimp->mat_imp
   Janela03.label_2.Value    := UPPER(siscpvimp->nome_imp)
   Janela03.label_3.Value    := DTOC(siscpvimp->dib_imp)
   Janela03.label_4.Value    := oSistema:MascaraNit(siscpvimp->nit_imp)
   Janela03.label_5.Value    := siscpvimp->sexo_imp
   Janela03.label_6.Value    := siscpvimp->cpf_imp
   Janela03.label_7.Value    := UPPER(siscpvimp->sitprc_imp)
   Janela03.label_8.Value    := UPPER(siscpvimp->motivo_imp)
   Janela03.label_9.Value    := siscpvimp->tipapo_imp
   Janela03.checkbox_1.Value := siscpvimp->falc_imp
   Janela03.label_10.Value   := DTOC(siscpvimp->datfal_imp)
   Janela03.checkbox_2.Value := IF(siscpvimp->sitprc_imp = "APROVADO",.T.,.F.)

   ENDIF
   
RETURN NIL
Paulo_CPV
Usuário Nível 3

Usuário Nível 3
 
Mensagens: 178
Data de registro: 07 Mar 2013 10:27
Cidade/Estado: Jacarei/SP
Curtiu: 0 vez
Mens.Curtidas: 1 vez

Dúvida urgente sobre comando GRID

Mensagempor Toledo » 10 Nov 2013 15:19

Olá Paulo, esta parte do seu código não tem como testar aqui, então fica difícil saber qual o erro que está ocorrendo.
Na sua mensagem anterior você disse que fez alterações no seu código com base no meu exemplo, mas se você observar no meu código, eu não uso o comando This.CellRowIndex.

Passe mais detalhes sobre o erro que está ocorrendo.

Abraços,
Toledo - Clipper On Line
toledo@pctoledo.com.br
Harbour 3.2/MiniGui/HwGui
Faça uma doação para o fórum, clique neste link: http://www.pctoledo.com.br/doacao
Avatar de usuário

Toledo
Administrador

Administrador
 
Mensagens: 3038
Data de registro: 22 Jul 2003 18:39
Cidade/Estado: Araçatuba - SP
Curtiu: 263 vezes
Mens.Curtidas: 258 vezes

Dúvida urgente sobre comando GRID

Mensagempor Paulo_CPV » 10 Nov 2013 21:58

Boa noite!

Amigo Toledo, obrigado pela sua atenção. Sim realmente fiz a alteração do seu exemplo posto aqui na minha função de atualizar os label's , mas mesmo assim ele não atualiza os Label's quando eu movimento a seta para cima ou para baixo no Grid. Não sei o que eu estou fazendo de errado para não atualizar os dados.

FUNCTION GridAtualizaDados()

   LOCAL nGrid := Janela03.grid_1.Value
   
   aGrid := Janela03.grid_1.Item(nGrid)
   
   cMat := aGrid[1]
   cNome := UPPER(aGrid[2])
   cDib := aGrid[3]
   
   Janela03.label_1.Value := cMat
   Janela03.label_2.Value := cNome
   Janela03.label_3.Value := cDib

RETURN .T.


Assim os label's ficam todos em branco

E se eu fizer desta maneira ele me mostra somente os dados da primeira linha do Grid.

FUNCTION GridAtualizaDados()

   LOCAL nPos := This.CellRowIndex
   
   aRet := Janela03.Grid_1.Item(nPos)
   
   SISCPVIMP->(DBSetOrder(3))
   SISCPVIMP->(DBGotop())
   SISCPVIMP->(DBSeek(aRet[2]))
   
   IF FOUND()
   
   Janela03.label_1.Value    := siscpvimp->mat_imp
   Janela03.label_2.Value    := UPPER(siscpvimp->nome_imp)
   Janela03.label_3.Value    := DTOC(siscpvimp->dib_imp)
   Janela03.label_4.Value    := oSistema:MascaraNit(siscpvimp->nit_imp)
   Janela03.label_5.Value    := siscpvimp->sexo_imp
   Janela03.label_6.Value    := siscpvimp->cpf_imp
   Janela03.label_7.Value    := UPPER(siscpvimp->sitprc_imp)
   Janela03.label_8.Value    := UPPER(siscpvimp->motivo_imp)
   Janela03.label_9.Value    := siscpvimp->tipapo_imp
   Janela03.checkbox_1.Value := siscpvimp->falc_imp
   Janela03.label_10.Value   := DTOC(siscpvimp->datfal_imp)
   Janela03.checkbox_2.Value := IF(siscpvimp->sitprc_imp = "APROVADO",.T.,.F.)

   ENDIF
   
RETURN NIL
Paulo_CPV
Usuário Nível 3

Usuário Nível 3
 
Mensagens: 178
Data de registro: 07 Mar 2013 10:27
Cidade/Estado: Jacarei/SP
Curtiu: 0 vez
Mens.Curtidas: 1 vez

Dúvida urgente sobre comando GRID

Mensagempor Toledo » 11 Nov 2013 06:18

Paulo, agora que observei que você está usando no Grid CELLNAVIGATION, então neste caso o retorno da propriedade VALUE é diferente.
Na sua função GridAtualizaDados(), tente o seguinte:

FUNCTION GridAtualizaDados()

   LOCAL aArr := Janela03.Grid_1.Value
   LOCAL nPos := aArr[1]
   
   aRet := Janela03.Grid_1.Item(nPos)
   
   SISCPVIMP->(DBSetOrder(3))
   SISCPVIMP->(DBGotop())
   SISCPVIMP->(DBSeek(aRet[2]))
   
   IF FOUND()
   
   Janela03.label_1.Value    := siscpvimp->mat_imp
   Janela03.label_2.Value    := UPPER(siscpvimp->nome_imp)
   Janela03.label_3.Value    := DTOC(siscpvimp->dib_imp)
   Janela03.label_4.Value    := oSistema:MascaraNit(siscpvimp->nit_imp)
   Janela03.label_5.Value    := siscpvimp->sexo_imp
   Janela03.label_6.Value    := siscpvimp->cpf_imp
   Janela03.label_7.Value    := UPPER(siscpvimp->sitprc_imp)
   Janela03.label_8.Value    := UPPER(siscpvimp->motivo_imp)
   Janela03.label_9.Value    := siscpvimp->tipapo_imp
   Janela03.checkbox_1.Value := siscpvimp->falc_imp
   Janela03.label_10.Value   := DTOC(siscpvimp->datfal_imp)
   Janela03.checkbox_2.Value := IF(siscpvimp->sitprc_imp = "APROVADO",.T.,.F.)

   ENDIF
   
RETURN NIL


Agora uma observação, no código acima tem um checkbox_1 que tem que receber o valor .T. ou .F.

Abraços,
Toledo - Clipper On Line
toledo@pctoledo.com.br
Harbour 3.2/MiniGui/HwGui
Faça uma doação para o fórum, clique neste link: http://www.pctoledo.com.br/doacao
Avatar de usuário

Toledo
Administrador

Administrador
 
Mensagens: 3038
Data de registro: 22 Jul 2003 18:39
Cidade/Estado: Araçatuba - SP
Curtiu: 263 vezes
Mens.Curtidas: 258 vezes

Dúvida urgente sobre comando GRID

Mensagempor Paulo_CPV » 11 Nov 2013 08:00

Bom dia, Toledo!

Amigo muito obrigado pela dica deu tudo certo aqui, funcionando 100%. Obrigado mesmo!Precisando de ajuda também estou aqui. Ah! E obrigado ao Pablo pelo auxilio também.

[]'s
Paulo - Jacareí/SP
Paulo_CPV
Usuário Nível 3

Usuário Nível 3
 
Mensagens: 178
Data de registro: 07 Mar 2013 10:27
Cidade/Estado: Jacarei/SP
Curtiu: 0 vez
Mens.Curtidas: 1 vez




Retornar para MiniGui

Quem está online

Usuários vendo este fórum: Nenhum usuário registrado online e 8 visitantes


Ola Amigo, espero que meu site e forum tem lhe beneficiado, com exemplos e dicas de programacao.
Entao divulgue o link da Doacao abaixo para seus amigos e redes sociais ou faça uma doacao para o site forum...
MUITO OBRIGADO PELA SUA DOACAO!
Faça uma doação para o forum
cron
v
Olá visitante, seja bem-vindo ao Fórum Clipper On Line!
Efetue o seu login ou faça o seu Registro