Clipper On Line • Ver Tópico - BAT de compilação

BAT de compilação

Aqui você poderá oferecer suas Contribuições, Dicas e Tutoriais (Texto ou Vídeo) que sejam de interesse de todos.

Moderador: Moderadores

 

BAT de compilação

Mensagempor JoséQuintas » 07 Out 2017 20:41

Tava aqui tentando organizar os BATs da HMG Extended....
É só um protótipo, que já postei lá no fórum dela.
Com certeza nem vou terminar, os BATs existentes são complicados, pra não dizer um lixo, e são pra XHarbour... e nem quero saber de testar.... então não adianta terminar..

Parece que bagunçam o Harbour, o XHarbour, e a vida dos programadores... kkkk é ensinar a desaprender, ou pra ninguém mexer...
Mas está aí, só comparar com os originais.
Lembrando que Harbour não precisa disso.

:Select
   IF "%1%" == "" GOTO :All
   IF "%1%" == "bostaurus" GOTO :bostaurus
   IF "%1%" == "propgrid"  GOTO :propgrid
   IF "%1%" == "tmsagent%" GOTO :tmsagent
   IF "%1%" == "tsbrowse%" GOTO :tsbrowse
   GOTO :End

:All

   CALL :bostaurus
   CALL :propgrid
   CALL :tmsagent
   CALL :tsbrowse
   CALL :winreport
   GOTO :End

:bostaurus

   SET LIBNAME=bostaurus
   SET LIBPATH=source\bostaurus
   SET PRGLIST=bostaurus
   SET CLIST=
   SET RCLIST=
   CALL :Compile
   GOTO :End

:propgrid

   SET LIBNAME=propgrid
   SET LIBPATH=source\propgrid
   SET PRGLIST=h_propgrid h_pglang
   SET CLIST=c_Propgrid
   SET CLIST=
   SET RCLIST=
   CALL :Compile
   GOTO :End

:tmsagent

   SET LIBNAME=tmsagent
   SET LIBPATH=source\tmsagent
   SET PRGLIST=tmsagent
   SET CLIST=
   SET RCLIST=
   CALL :Compile
   GOTO :End

:tsbrowse

   SET LIBNAME=tsbrowse
   SET LIBPATH=source\tsbrowse
   SET PRGLIST=tcontrol tscolumn scrllbar tcombobox tdatepicker tbtnbox
   SET PRGLIST=%PRGLIST% tgetbox tsmulti tcursor
   rem multilingual
   SET PRGLIST=%PRGLIST% sbmsg
   rem addition functions
   SET PRGLIST=%PRGLIST% h_controlmisc1
   SET CLIST=
   SET RCLIST=
   CALL :Compile
   GOTO :End

:winreport

   SET LIBNAME=winreport
   SET LIBPATH=source\winreport
   SET PRGLIST=h_wrepint h_wremix h_wrepdf hmg_hpdf fncmyerror
   SET CLIST=
   SET RCLIST=
   CALL :Compile
   GOTO :End

:Compile

   SET LINKLIST=
   IF NOT "%PRGLIST%" == "" FOR %%A IN ( PRGLIST ) CALL :CompilePRG %%A.prg
   IF NOT "%CLIST%"   == "" FOR %%A IN ( CLIST )   CALL :CompileC %%a.c
   IF NOT "%PRGLIST%%CLIST%" == "" CALL :Link
   SET LINKLIST=
   GOTO :End

:CompilePRG

   IF NOT ERRORLEVEL 1 %MV_HRB%\bin\harbour %LIBPATH%\%1.prg -n1 -w2 -gc0 -i%MV_HRB%\include;%MG_ROOT%\include
   IF NOT ERRORLEVEL 1 %MG_BCC%\bin\bcc32 %1.c -c -O2 -tWM -d -6 -OS -I%MV_HRB%\include;%MG_BCC%\include;%MG_ROOT%\include -L%MV_HRB%\lib;%MG_BCC%\lib
   SET LINKLIST=%LINKLIST% +%1.obj
   GOTO :End

:CompileC

  IF NOT ERRORLEVEL 1 %MG_BCC%\bin\bcc32 %1.c -c -tWM -O2 -d -6 -OS -I.;%MV_HRB%\include;%MG_ROOT%\include -L%MV_HRB%\lib;%MG_BCC%\lib
  GOTO :End

:Link
   IF NOT ERRORLEVEL 1 IF EXIST lib\xhb\%LIBNAME%.lib DEL lib\xhb\%LIBNAME%.lib
   IF NOT ERRORLEVEL 1 %MG_BCC%\bin\tlib lib\xhb\tsbrowse.lib %LINKLIST%
   IF EXIST lib\xhb\%LIBNAME%.bak DEL lib\xhb\%LIBNAME%.bak
   GOTO :End

:End


Ou se quiserem ver num formato mais interessante, só olhar pelo GitHub

https://github.com/JoseQuintas/hhmge/blob/master/test.bat

Nota:
Só treino de BAT.
"Criar função" nos bats foi descoberta recente, menos de um ano.
Nem sei desde quando existe isso. CALL :Rotina parâmetros

Nota2:
Não sou expert, conheço pouca coisa, mas essa pouca coisa... eu conheço....
O que eu não souber, resolvo usando o pouco que já conheço... rs

É por isso que gostaria de participar das LIBs, remover muito lixo de tudo....
Quem sabe depois de remover o lixo se encontra alguma coisa escondida....
José M. C. Quintas
Harbour 3.2, mingw, gtwvg, multithread, dbfcdx, ADO+MySql, PNotepad
"The world is full of kings and queens, who blind our eyes and steal our dreams Its Heaven and Hell"

https://github.com/JoseQuintas/
Avatar de usuário

JoséQuintas
Membro Master

Membro Master
 
Mensagens: 17942
Data de registro: 26 Fev 2007 11:59
Cidade/Estado: São Paulo-SP
Curtiu: 15 vezes
Mens.Curtidas: 1206 vezes

BAT de compilação

Mensagempor JoséQuintas » 08 Out 2017 10:45

Um erro na rotina de liquedição, tá com nome fixo de tsbrowse, e deveria ser o nome de cada lib. (LIBNAME)

:Link
IF NOT ERRORLEVEL 1 IF EXIST lib\xhb\%LIBNAME%.lib DEL lib\xhb\%LIBNAME%.lib
IF NOT ERRORLEVEL 1 %MG_BCC%\bin\tlib lib\xhb\%LIBNAME%.lib %LINKLIST%
IF EXIST lib\xhb\%LIBNAME%.bak DEL lib\xhb\%LIBNAME%.bak
GOTO :End
José M. C. Quintas
Harbour 3.2, mingw, gtwvg, multithread, dbfcdx, ADO+MySql, PNotepad
"The world is full of kings and queens, who blind our eyes and steal our dreams Its Heaven and Hell"

https://github.com/JoseQuintas/
Avatar de usuário

JoséQuintas
Membro Master

Membro Master
 
Mensagens: 17942
Data de registro: 26 Fev 2007 11:59
Cidade/Estado: São Paulo-SP
Curtiu: 15 vezes
Mens.Curtidas: 1206 vezes

BAT de compilação

Mensagempor JoséQuintas » 08 Out 2017 10:56

Faltou o teste prático, mostrar da bostaurus, porque é o menor e fica um post pequeno.

d:\CVSFiles\oohg>test bostaurus

ONLY TEST, DO NOT USE IT
Help to compile using XHarbour
Not the fatest mode, because is individual file compile

bostaurus if not errorlevel 1 harbour \bostaurus.prg -i"\include;\include" -n1 -w3 -gc0 -es2
bostaurus if not errorlevel 1 bcc needpath\bostaurus.c -iinclude need complete
bostaurus if not errorlevel 1 ilink bostaurus need complete


A rotina :Choice exectou apenas a rotina :bostaurus
A rotina :bostaurus configurou e chamou a compilação :Compile
A rotina :Compile chamou a compilação de PRG e linquedição (:CompilePRG e :Link)
A rotina :CompiePRG compilou com XHarbour e C
A rotina :Link apenas linqueditou.

Já na versão seguinte, alterei pra :CompilePRG e :CompileC adicionarem parâmetros a uma lista de linquedição (LINKLIST)
É porque o OBJ pode estar em outra pasta, não na pasta atual, então não serve o nome original.
José M. C. Quintas
Harbour 3.2, mingw, gtwvg, multithread, dbfcdx, ADO+MySql, PNotepad
"The world is full of kings and queens, who blind our eyes and steal our dreams Its Heaven and Hell"

https://github.com/JoseQuintas/
Avatar de usuário

JoséQuintas
Membro Master

Membro Master
 
Mensagens: 17942
Data de registro: 26 Fev 2007 11:59
Cidade/Estado: São Paulo-SP
Curtiu: 15 vezes
Mens.Curtidas: 1206 vezes

BAT de compilação

Mensagempor JoséQuintas » 08 Out 2017 11:15

Aproveitando....

Se for por PRG ao invés de BAT melhor ainda.
Deve ter sido assim que o HBMK2 começou, e foi evoluindo.
Só fazer o mesmo pra XHarbour.
Aí vai dar pra dividir os fontes em blocos, pra fazer menos chamadas ao compilador, e deixar tudo mais rápido.

harbour fonte1 fonte2 fonte3 fonte4 fonte5
harbour fonte6 fonte7 fonte8
bcc fonte1 fonte2 fonte3
bcc fonte4 fonte5fonte6

Pois é....
Se criam BAT pra fazer diferente, poderiam criar um PRG e já fazer igual, pra simplificar tudo.... rs
Melhor para os programadores, estaria tudo padronizado, todo mundo aprendendo cada vez mais, ou sobrando tempo pra coisas mais importantes.
José M. C. Quintas
Harbour 3.2, mingw, gtwvg, multithread, dbfcdx, ADO+MySql, PNotepad
"The world is full of kings and queens, who blind our eyes and steal our dreams Its Heaven and Hell"

https://github.com/JoseQuintas/
Avatar de usuário

JoséQuintas
Membro Master

Membro Master
 
Mensagens: 17942
Data de registro: 26 Fev 2007 11:59
Cidade/Estado: São Paulo-SP
Curtiu: 15 vezes
Mens.Curtidas: 1206 vezes

BAT de compilação

Mensagempor JoséQuintas » 08 Out 2017 11:49

Pequeno protótipo em PRG.
Entra tudo bagunçado e sai separado.

compprg.png


test.prg
(3.61 KiB) Baixado 98 vezes
José M. C. Quintas
Harbour 3.2, mingw, gtwvg, multithread, dbfcdx, ADO+MySql, PNotepad
"The world is full of kings and queens, who blind our eyes and steal our dreams Its Heaven and Hell"

https://github.com/JoseQuintas/
Avatar de usuário

JoséQuintas
Membro Master

Membro Master
 
Mensagens: 17942
Data de registro: 26 Fev 2007 11:59
Cidade/Estado: São Paulo-SP
Curtiu: 15 vezes
Mens.Curtidas: 1206 vezes

BAT de compilação

Mensagempor JoséQuintas » 08 Out 2017 11:59

Aproveitando...

Está aí um bom exemplo de #define.
Dá pra imaginar esse fonte sem isso?
O que seria aCompile[ 1, 3 ] ?
Mais fácil aCompile[ CMD_FILE_PRG, 3 ), se refere a arquivos prg.(file prg)

Ou exemplo de FOR/EACH
CASE oElement == "-w0" ; nType := CMD_FLAG_PRG
É trabalhar com um elemento, uma "palavra" de cada vez no fonte.

O fonte fica mais legível, pelo menos pra quem já se acostumou com isso.

E pensar que antigamente eu achava frescura isso, que só complicava.... rs
José M. C. Quintas
Harbour 3.2, mingw, gtwvg, multithread, dbfcdx, ADO+MySql, PNotepad
"The world is full of kings and queens, who blind our eyes and steal our dreams Its Heaven and Hell"

https://github.com/JoseQuintas/
Avatar de usuário

JoséQuintas
Membro Master

Membro Master
 
Mensagens: 17942
Data de registro: 26 Fev 2007 11:59
Cidade/Estado: São Paulo-SP
Curtiu: 15 vezes
Mens.Curtidas: 1206 vezes

BAT de compilação

Mensagempor JoséQuintas » 31 Out 2017 12:38

Nessa brincadeira de mexer em bats, andei descobrindo umas coisas novas.

@echo off
:MAIN

   for %%a in ( 0 1 2 3 4 5 6 ) do call :show %%a
   goto :END

:Show
   if %1==1 (
      echo primeiro ) ^
   else if %1==2 (
      echo segundo ) ^
   else if %1==3 (
      echo terceiro ) ^
   else if %1==4 (
      echo quarto ) ^
   else if %1==5 (
      echo quinto ) ^
   else (
      echo desconhecido )
   goto :END

:END


resultado na tela:

d:\temp>test.bat
desconhecido
primeiro
segundo
terceiro
quarto
quinto
desconhecido


interessante....
José M. C. Quintas
Harbour 3.2, mingw, gtwvg, multithread, dbfcdx, ADO+MySql, PNotepad
"The world is full of kings and queens, who blind our eyes and steal our dreams Its Heaven and Hell"

https://github.com/JoseQuintas/
Avatar de usuário

JoséQuintas
Membro Master

Membro Master
 
Mensagens: 17942
Data de registro: 26 Fev 2007 11:59
Cidade/Estado: São Paulo-SP
Curtiu: 15 vezes
Mens.Curtidas: 1206 vezes

BAT de compilação

Mensagempor asimoes » 31 Out 2017 15:55

Será que tem vaga para programador de Bats, kkkk
Valeu Quintas pela contribuição
â–ºHarbour 3.x | Minigui xx-x | HwGuiâ—„
Pense nas possibilidades abstraia as dificuldades.
Não corrigir nossas falhas é o mesmo que cometer novos erros.
A imaginação é mais importante que o conhecimento. (Albert Einstein)
Avatar de usuário

asimoes
Colaborador

Colaborador
 
Mensagens: 4919
Data de registro: 26 Abr 2007 16:48
Cidade/Estado: RIO DE JANEIRO-RJ
Curtiu: 341 vezes
Mens.Curtidas: 258 vezes

BAT de compilação

Mensagempor JoséQuintas » 03 Nov 2017 19:59

Ainda falta a parte de linquedição, mas o mais engraçado é descobrir que realmente é tudo a mesma coisa.
O pessoal do XHarbour não usa o HBMK2 porque não quer.
O detalhe é que é obrigatório acrescentar -xhb, porque o HBMK2 tem compilador Harbour embutido, ele NÃO precisa do HARBOUR.EXE.
A indicação de -xhb desativa o Harbour interno, e usa o Harbour.exe

Mas o trem é muito doido.... rs
Com certeza, nem chega aos pés do HBMK2.
Acabei considerando um desafio interessante tentar fazer por bat, já que parece que nunca vão retirar os BATs das LIBs....

Apenas mostra os possíveis comandos na tela, não executa nada.
Ainda falta a parte de linquedição que é a mais complicada.

Chamei de HGFUNC.BAT, pois trata-se de um arquivo de "funções".... rs
Ia chamar de HGClass.BAT, porque tem variáveis e métodos... rs.... mas achei ruim pra digitar.
É sério... lembrando que GOTO desvia a rotina, mas CALL executa e volta, e não precisa ser um BAT externo, pode ser rotina interna.

Tem até teste embutido.
Precisam existir os fontes passados em TEST_EACH (dentro do bat), pode ser PRG ou C, mas sem extensão.
Existindo os fontes, é só digitar HGFUNC test
Vai mostrar 4 versões diferentes de compilação, com pausa entre elas, pra BCC, POCC, MSVC e MINGW.
Lembrando que falta a linquedição ainda....

Nunca pensei que dava pra fazer coisas assim com BAT... rs

@echo off
rem   HGFUNC
rem   (Test only, not in use)
rem
rem   example: call :HGFUNC COMPILER RESET
rem
rem   OOHG Variables
rem
rem   HG_ROOT       - root path OOHG
rem   HG_ROOT_HB    - root path Harbour/XHarbour
rem   HG_ROOT_C     - root path C compiler
rem   HG_COMP_HB    - HB30, HB32, XB
rem   HG_COMP_C     - bcc, mingw, msvc, pocc
rem   HG_PRG_FLAGS  - additional PRG Flags
rem   HG_PRG_FLAGSL - -q0 1^>error.lst 2^>^&1
rem   HG_C_FLAGS    - additional C Flags
rem   HG_C_FLAGSL   - 1^>error.lst 2^>^&1
rem   HG_PRG_LIST   - list of PRG files WITHOUT extension
rem   HG_C_LIST     - list of C files WITHOUT extension
rem

:HGFUNC

   if /i "%1"=="TEST" goto :TEST_ALL
   if /i "%1"=="COMPILER" if /i "%2"=="RESET" goto :SET_COMP_RESET
   if /i "%1"=="COMPILER" if /i "%2"=="HB30"  goto :SET_COMP_HB30
   if /i "%1"=="COMPILER" if /i "%2"=="HB32"  goto :SET_COMP_HB32
   if /i "%1"=="COMPILER" if /i "%2"=="XB"    goto :SET_COMP_XB
   if /i "%1"=="COMPILE"     goto :BUILD_PREPARE
   if /i "%1"=="COMPILE_PRG" goto :COMPILE_ALL_PRG
   if /i "%1"=="COMPILE_C"   goto :COMPILE_ALL_C
   goto :END

:TEST_ALL

   call :HGFUNC COMPILER RESET
   set HG_COMP_C=bcc
   call :TEST_EACH
   pause
   call :HGFUNC COMPILER RESET
   set HG_COMP_C=pocc
   call :TEST_EACH
   pause
   call :HGFUNC COMPILER RESET
   set HG_COMP_C=msvc
   call :TEST_EACH
   pause
   call :HGFUNC COMPILER RESET
   set HG_COMP_C=mingw
   call :TEST_EACH
   pause
   goto :END

:TEST_EACH

   rem ---------- call :HGFUNC COMPILER RESET
   call :HGFUNC COMPILER HB30
   cd source
   call :HGFUNC COMPILE ^
      h_activex h_anigif h_application h_browse h_button ^
         c_windows
   rem ----------      h_checkbox h_checklist h_combo h_comm h_controlmisc h_crypt h_cursor ^
   rem ----------      h_datepicker h_dialogs h_dll h_edit h_editbox h_edit_ex h_error ^
   rem ----------      h_font h_form h_frame h_graph h_grid h_help h_hotkey h_hotkeybox ^
   rem ----------      h_hyperlink h_image h_ini h_init h_internal h_ipaddress h_label ^
   rem ----------      h_listbox h_media h_menu h_monthcal h_msgbox h_notify h_pdf ^
   rem ----------      h_picture h_print h_progressbar h_progressmeter h_radio h_registry ^
   rem ----------      h_report h_richeditbox h_scroll h_scrollbutton h_scrsaver h_slider ^
   rem ----------      h_spinner h_splitbox h_status h_tab h_textarray h_textbox h_timer ^
   rem ----------      h_toolbar h_tooltip h_tree h_winapimisc h_windows h_xbrowse h_zip ^
   rem ----------      c_activex c_controlmisc c_cursor c_dialogs c_font c_gdiplus c_graph ^
   rem ----------      c_image c_media c_msgbox c_progressbar c_resource c_scrsaver c_winapimisc ^

   cd ..
   goto :END

:SET_COMP_RESET

   set HG_ROOT=c:\oohg
   set HG_COMP_HB=
   set HG_COMP_C=
   set HG_ROOT_HB=
   set HG_ROOT_C=
   call :SET_PROJECT_RESET
   goto :END

:SET_PROJECT_RESET

   set HG_C_FLAGS=
   set HG_C_FLAGSL=
   set HG_PRG_FLAGS=
   set HG_PRG_FLAGSL=
   set HG_PRG_LIST=
   set HG_C_LIST=
   goto :END

:SET_COMP_HB30

   if "%HG_ROOT%"==""    set HG_ROOT=c:\oohg
   if "%HG_COMP_HB%"=="" set HG_COMP_HB=HB30
   rem ---------- if "%HG_COMP_C%"==""  set HG_COMP_C=mingw
   if "%HG_ROOT_HB%"=="" set HG_ROOT_HB=c:\oohg\hb30
   if "%HG_ROOT_C%"==""  set HG_ROOT_C=c:\oohg\hb30\comp\mingw
   goto :END

:SET_COMP_HB32

   if "%HG_ROOT%"==""    set HG_ROOT=c:\oohg
   if "%HG_COMP_HB%"=="" set HG_COMP_HB=HB32
   rem ---------- if "%HG_COMP_C%"==""  set HG_COMP_C=mingw
   if "%HG_ROOT_HB%"=="" set HG_ROOT_HB=c:\oohg\hb32
   if "%HG_ROOT_C%"==""  set HG_ROOT_C=c:\oohg\hb32\comp\mingw
   goto :END

:SET_COMP_XB

   if "%HG_ROOT%"==""    set HG_ROOT=c:\oohg
   if "%HG_COMP_HB%"=="" set HG_COMP_HB=XB
   rem ---------- if "%HG_COMP_C%"==""  set HG_COMP_C=bcc
   if "%HG_ROOT_HB%"==""  set HG_ROOT_HB=c:\oohg\xhbcc
   if "%HG_ROOT_C%"==""   set HG_ROOT_C=c:\Borland\BCC55
   goto :END

:BUILD_PREPARE

   shift
   if "%1"=="" goto :BUILD_PROJECT
   if exist %1.prg set HG_PRG_LIST=%HG_PRG_LIST% %1
   if exist %1.c   set HG_C_LIST=%HG_C_LIST% %1
   if exist %1.rc  set HG_RC_LIST=%HG_RC_LIST% %1
   goto :BUILD_PREPARE

:BUILD_PROJECT

   call :COMPILE_ALL_PRG
   call :COMPILE_ALL_C
   call :LINK
   set HG_PRG_LIST=
   set HG_C_LIST=
   goto :END

:COMPILE_ALL_PRG

   if not "%HG_PRG_LIST%"=="" for %%a in ( %HG_PRG_LIST% ) do call :COMPILE_PRG %%a
   goto :END

:COMPILE_PRG

   if not errorlevel 1 echo %HG_ROOT_HB%\bin\harbour %1.prg -n1 %HG_PRG_FLAGS% -i%HG_ROOT_HB%\include;%HG_ROOT%\include;. %HG_PRG_FLAGSL%
   echo.
   call :COMPILE_C %1
   goto :END

:COMPILE_ALL_C

   if not "%HG_C_LIST%"=="" for %%a in ( %HG_C_LIST% ) do call :COMPILE_C %%a
   goto :END

:COMPILE_C

   if /I "%HG_COMP_C%"=="BCC"   goto :COMPILE_BCC
   if /I "%HG_COMP_C%"=="MINGW" goto :COMPILE_MINGW
   if /I "%HG_COMP_C%"=="MSVC"  goto :COMPILE_MSVC
   if /I "%HG_COMP_C%"=="POCC"  goto :COMPILE_POCC
   goto :END

:COMPILE_BCC

   echo %HG_ROOT_C%\bin\bcc32 -c -O2 -tW -M -w -I%HG_ROOT_HB%\include;%HG_ROOT_C%\include;%HG_ROOT%\include; -L%HG_ROOTC%\lib; -D__XHARBOUR__ %1.c %HG_C_FLAGSL%
   echo.
   goto :END

:COMPILE_MINGW

   echo %HG_ROOT_C%\bin\gcc -W -Wall -O3 -c -I%HG_ROOT_HB%\include -I%HG_ROOT_C%\include -I%HG_ROOT%\include -L%HG_ROOT_HB%\%LIB_HRB% -L%HG_ROOT_C%\lib %1.c %HG_C_FLAGSL%
   echo.

   goto :END

:COMPILE_MSVC

   echo %HG_ROOT_C%\bin\cl /O2 /c /TP /I%HG_ROOT_HB%\include /I%HG_ROOT_C%\include /I%HG_ROOT%\include /I. /D__WIN32__ %1.c %HG_C_FLAGSL%
   echo.
   goto :END

:COMPILE_POCC

   echo %HG_ROOT_C%\bin\pocc /Ze /Zx /Go /Tx86-coff /I%HG_ROOT_C%\include /I%HG_ROOT_C%\include\Win /I%HG_ROOT_HB%\include /I%HB_ROOT%\include /D__WIN32__ %1.c %HG_C_FLAGSL%
   echo.

   goto :END

:LINK

   if /I "%HG_COMP_C%"=="BCC"   goto :LINK_BCC
   if /I "%HG_COMP_C%"=="MINGW" goto :LINK_MINGW
   if /I "%HG_COMP_C%"=="MSVC"  goto :LINK_MSVC
   if /I "%HG_COMP_C%"=="POCC"  goto :LINK_POCC
   goto :END

:LINK_BCC

   echo BCC LINK
   echo %HG_PRG_LIST% %HG_OBJ_LIST%
   goto :END

:LINK_MINGW

   echo MINGW LINK
   echo %HG_PRG_LIST% %HG_OBJ_LIST%
   goto :END

:LINK_MSVC

   echo MSVC LINK
   echo %HG_PRG_LIST% %HG_OBJ_LIST%
   goto :END

:LINK_POCC

   echo POCC LINK
   echo %HG_PRG_LIST% %HG_OBJ_LIST%
   goto :END

:END
José M. C. Quintas
Harbour 3.2, mingw, gtwvg, multithread, dbfcdx, ADO+MySql, PNotepad
"The world is full of kings and queens, who blind our eyes and steal our dreams Its Heaven and Hell"

https://github.com/JoseQuintas/
Avatar de usuário

JoséQuintas
Membro Master

Membro Master
 
Mensagens: 17942
Data de registro: 26 Fev 2007 11:59
Cidade/Estado: São Paulo-SP
Curtiu: 15 vezes
Mens.Curtidas: 1206 vezes




Retornar para Contribuições, Dicas e Tutoriais

Quem está online

Usuários vendo este fórum: Nenhum usuário registrado online e 2 visitantes


Ola Amigo, espero que meu site e forum tem lhe beneficiado, com exemplos e dicas de programacao.
Entao divulgue o link da Doacao abaixo para seus amigos e redes sociais ou faça uma doacao para o site forum...
MUITO OBRIGADO PELA SUA DOACAO!
Faça uma doação para o forum
cron
v
Olá visitante, seja bem-vindo ao Fórum Clipper On Line!
Efetue o seu login ou faça o seu Registro