Clipper On Line • Ver Tópico - Exemplo simples de gtwvg

Exemplo simples de gtwvg

Aqui você poderá oferecer suas Contribuições, Dicas e Tutoriais (Texto ou Vídeo) que sejam de interesse de todos.

Moderador: Moderadores

 

Exemplo simples de gtwvg

Mensagempor JoséQuintas » 21 Out 2013 05:01

Pra quem se perdeu com os exemplos da gtwvg, aqui vai um exemplo simples.
Precisa só salvar um bmp na pasta com o nome policial.bmp.

#include "wvtwin.ch"

PROCEDURE Main
   SetMode(25,80)
   CLS
   ToolBar()
   StatusBar()
   Button()
   Progressbar()
   Inkey(0)
   RETURN

STATIC FUNCTION Progressbar()
   LOCAL oProgressbar, nCont
   oProgressbar := wvtProgressbar():New( wvgSetAppWindow(), , 10, 10, 15, 60 )
   oProgressbar:Create()
   oProgressbar:Activate()
   FOR nCont = 1 TO 100
      oProgressBar:Display( nCont, 100 )
      Inkey(0.1)
   NEXT
   RETURN NIL

STATIC FUNCTION StatusBar()
   LOCAL oStatusBar, oPanel
   oStatusBar := wvgStatusBar():New( wvgSetAppWindow() ):Create( , , , , , .T. )
   oPanel := oStatusBar:GetItem(1)
   oPanel:Caption := "Test of status bar"
   RETURN NIL

STATIC FUNCTION Toolbar()
   LOCAL oToolbar, cDirIcon := "JPAICON\"
   oToolbar := WvgToolBar():New( wvgSetAppWindow(), , { 0, 0 }, { 0, 0 }, , .T. )
   oToolbar:style        := WVGTOOLBAR_STYLE_FLAT
   oToolbar:borderStyle  := WVGFRAME_RECT
   oToolbar:buttonWidth  := 32
   oToolbar:buttonHeight := 32
   oToolbar:imageWidth   := 32
   oToolbar:imageHeight  := 32
   oToolbar:showToolTips := .T.
   oToolbar:Create()
   oToolbar:addItem( "New"       , "policial.bmp" )
   oToolbar:AddItem( "Select"    , "policial.bmp" )
   oToolbar:AddItem()
   oToolbar:AddItem( "FontDlg"   , "policial.bmp" )
   oToolbar:AddItem( "Tools"     , "policial.bmp" )
   oToolbar:AddItem( "Index"     , "policial.bmp" )
   oToolbar:AddItem()
   oToolbar:AddItem( "Show"      , "policial.bmp" )
   oToolbar:AddItem( "Hide"      , "policial.bmp" )
   oToolbar:ButtonClick := { | oBtn | wapi_Messagebox( wapi_GetActiveWindow(), oBtn:Caption, "toolbar", MB_ICONASTERISK ) }
   RETURN NIL

STATIC FUNCTION Button()
   LOCAL oThisButton, nCont
   FOR nCont = 1 TO 10
      oThisButton := wvgPushButton():New()
      oThisButton:Caption := Ltrim( Str( nCont ) )
      oThisButton:PointerFocus := .F.
      oThisButton:Create( , , { -18, -nCont * 5 }, { -2, -4 } )
      oThisButton:Activate := { | oBtn | wapi_MessageBox( wapi_GetActiveWindow(), oBtn:Caption, "button", MB_ICONASTERISK ) }
   NEXT
   RETURN NIL


arquivo hbp

test.prg
errorsys.prg
gtwvg.hbc
-compr
-strip
José M. C. Quintas
Harbour 3.2, mingw, gtwvg, multithread, dbfcdx, ADO+MySql, PNotepad
"The world is full of kings and queens, who blind our eyes and steal our dreams Its Heaven and Hell"

https://github.com/JoseQuintas/
Avatar de usuário

JoséQuintas
Membro Master

Membro Master
 
Mensagens: 18010
Data de registro: 26 Fev 2007 11:59
Cidade/Estado: São Paulo-SP
Curtiu: 15 vezes
Mens.Curtidas: 1206 vezes

Exemplo simples de gtwvg

Mensagempor JoséQuintas » 21 Out 2013 05:03

a tela:
Anexos
gtwvg2.png
José M. C. Quintas
Harbour 3.2, mingw, gtwvg, multithread, dbfcdx, ADO+MySql, PNotepad
"The world is full of kings and queens, who blind our eyes and steal our dreams Its Heaven and Hell"

https://github.com/JoseQuintas/
Avatar de usuário

JoséQuintas
Membro Master

Membro Master
 
Mensagens: 18010
Data de registro: 26 Fev 2007 11:59
Cidade/Estado: São Paulo-SP
Curtiu: 15 vezes
Mens.Curtidas: 1206 vezes

Exemplo simples de gtwvg

Mensagempor JoséQuintas » 21 Out 2013 05:06

tem este outro exemplo, mas ainda não tentei simplificar.
Está misturado nos testes da gtwvg, o fonte faz parte do demowvg.
Como é a tal janela de diálogo, precisa de uma janela principal, que é a que está de fundo.

O problema é falta de exemplos simples e manuais.
Por exemplo: não existe fonte usando a tabcontrol, apesar de existir.
A wvg está preparada pra criar qualquer controle nela mesma, em fonte prg.
É por isso que eu acho a gtwvg a mais interessante das GUIs.
O chato é que criar controles não é pra nós pobres utilizadores de controles prontos.
Anexos
gtwvg.png
José M. C. Quintas
Harbour 3.2, mingw, gtwvg, multithread, dbfcdx, ADO+MySql, PNotepad
"The world is full of kings and queens, who blind our eyes and steal our dreams Its Heaven and Hell"

https://github.com/JoseQuintas/
Avatar de usuário

JoséQuintas
Membro Master

Membro Master
 
Mensagens: 18010
Data de registro: 26 Fev 2007 11:59
Cidade/Estado: São Paulo-SP
Curtiu: 15 vezes
Mens.Curtidas: 1206 vezes

Exemplo simples de GTWVG

Mensagempor clodoaldomonteiro » 25 Out 2019 13:44

Quintas,

No arquivo .HBP cita o arquivo ErrorSys.PRG, que não existe no projeto.
At. Clodoaldo Monteiro
Linguagens: Clipper / Harbour
Área de Atuação: Sistemas de gestão para Prefeituras Municipais
Fones: (86)3223-0653, 98859-0236
www.simplesinformatica.com.br
Avatar de usuário

clodoaldomonteiro
Usuário Nível 4

Usuário Nível 4
 
Mensagens: 741
Data de registro: 30 Dez 2006 12:17
Cidade/Estado: Teresina-PI
Curtiu: 110 vezes
Mens.Curtidas: 31 vezes

Exemplo simples de gtwvg

Mensagempor JoséQuintas » 25 Out 2019 22:51

pode usar a padrão mesmo, pro teste.
José M. C. Quintas
Harbour 3.2, mingw, gtwvg, multithread, dbfcdx, ADO+MySql, PNotepad
"The world is full of kings and queens, who blind our eyes and steal our dreams Its Heaven and Hell"

https://github.com/JoseQuintas/
Avatar de usuário

JoséQuintas
Membro Master

Membro Master
 
Mensagens: 18010
Data de registro: 26 Fev 2007 11:59
Cidade/Estado: São Paulo-SP
Curtiu: 15 vezes
Mens.Curtidas: 1206 vezes




Retornar para Contribuições, Dicas e Tutoriais

Quem está online

Usuários vendo este fórum: Nenhum usuário registrado online e 15 visitantes


Ola Amigo, espero que meu site e forum tem lhe beneficiado, com exemplos e dicas de programacao.
Entao divulgue o link da Doacao abaixo para seus amigos e redes sociais ou faça uma doacao para o site forum...
MUITO OBRIGADO PELA SUA DOACAO!
Faça uma doação para o forum
cron
v
Olá visitante, seja bem-vindo ao Fórum Clipper On Line!
Efetue o seu login ou faça o seu Registro