Elgin L42 Etiquetas

[Alexandre Silva]

Pessoal
O manual diz que é compativel com PPLA, mas nao tive sucesso
Eu sempre faco um arquivo txt, e mando via dosprint, funciona 100%\ para Argox
@ DOSPrint.exe /LngBR /raw /sel'BTP-L42(U)' ETQB.TXT

Tambem tentei via BPLB, como anexo
A impressora nao responde
Pelo software Bylabel que vem com ela, funciona..

alguma dica ?

[Itamar M. Lins Jr.]

Olá!
Usando o ByLabel imprime em arquivo e vê como é, se PPLA ou PPLB.
Eu desenhava a etiqueta usando o software da argox, imprimo em arquivo, pego o modelo e modifico o TXT, para não perder tempo.

Saudações,
Itamar M. Lins Jr.

[Alexandre Silva]

Sim, Eu faço isso com a Argox, é otimo, imprime em arquivo txt PLPA

MAS
para a Elgin, eu tentei com o ByLabel e com o Barterder, ambos, quando for ELGIN, o formato é NAO É texto..Pode ver no Anexo

A etiqueta tem uma area util de 104 mm de largura por 139 mm de altura

Na linguagem PLPB, eu ate consgegui fazer a etiqueta, mas nao consigo fazer ela comecar ou terminar dentro do etiqueta
ou no meio, ou termina antes, out depois, Ai fica bipando..

Abaixo.
Comando JF que seria (habilita o “backfeed” para que ao final da impressão, o espaço entre etiquetas pare na serrilha) NAO FUNCIONA

Comando Qp1,p2
p1 que seria a altura em pontos, sendo que 8 mm é um ponto, entao sao 139 mm, 1112 pontoS ( nao sei se é isso)
p2 Altura do espacamento do Gap, so 5 mm entao 40 pontos

** RESUMINDO, meu problema é fazer começar certo e terminar dentro da etiqueta
Nao sei se falta algo ai..

N
O
D9
S3
JF
Q1112,40
q832
A730,0,1,5,1,1,N,"NOME DA EMPRESA"
A610,0,1,5,1,2,N,"NF: 2097272"
A460,0,1,5,1,2,N,"ROTA: 451233"
A300,0,1,5,1,2,N,"PEDIDO: 1234564"
A160,0,1,5,1,2,N,"PALET: 1/1 "
P1

[Itamar M. Lins Jr.]

Olá!
Tem manual em PDF com exemplos ?

Saudações,
Itamar M. Lins Jr.

[paiva_dbdc]

Alexandre

Eu ate tenho essa impressora a + de ano rs

COMPREI enganado pensando que estava comprando a zebra

na época tentei e Não consegui fazer funcionar ai liguei la no suporte deles e o Tec acessou minha maquina e fez umas atualizações

Pelo que entendi o problema era o software dela

ai funcionou testei na epoca === a ZEBRA que meus clientes usam,

a um tempo atraz formatei meu PC.

tambem NAO tentei usar denovo ela

vou ver se acho um tempo para ver se esta funcionando ok

[malcarli]

Segue teste funcionando. Minigui extended com harbour.

/*****************************************************************************
 * SISTEMA  : ROTINA EVENTUAL                                                *
 * PROGRAMA : ETQ_ELGIN.PRG                                              *
 * OBJETIVO : Etiqueta com Código de Barras na Impressora Elgin + Lib hbwin  *
 * AUTOR    : Marcelo Antonio Lázzaro Carli                                  *
 * DATA     : 24.11.2014                                                     *
 * ULT. ALT.: 28.11.2014                                                     *
 *****************************************************************************/
#include <minigui.ch>

Function Main()
   REQUEST HB_LANG_PT
   HB_LangSelect([PT])
   REQUEST HB_CODEPAGE_PT850 &&& PARA INDEXAR CAMPOS ACENTUADOS
   HB_SETCODEPAGE([PT850])   &&& PARA INDEXAR CAMPOS ACENTUADOS

   Set wrap on
   Set talk off
   Set date briti             &&& data no formato dd/mm/aaaa
   Set dele on                &&& ignora registros marcados por deleção
   Set score off
   Set exact on
   Set ToolTip on
   Setcancel(.F.)             &&& evitar cancelar sistema c/ ALT + C
   Set cent on                &&& ano com 4 dígitos
   Set epoch to 2000          &&& ano a partir de 2000
   Set excl off               &&& abre arquivos em modo compartilhado
   Set navigation extended    &&& enter no lugar do tab
   Set language to portuguese &&& mensagens em português
   Set multiple off warning   &&& abrir 1 cópia somente
   Set browsesync on          &&& para o comando browse funcionar ok
   Set tooltipstyle balloon   &&& para mensagem dos campos em forma de balão
   Set menustyle extended     &&& padrão é standard, extended estilo office 2007
   Set programmaticchange off &&& introduzida na build 1.9.94

   Define window main at 0, 0 width 300 height 300 title [Impressão de Etiquetas - Elgin 2 Carreiras] ICON [demo.ico] NOTIFYICON [demo.ico] MAIN NOSIZE NOMAXIMIZE ON INIT {|| Criar_Arquivos()} ON Release {|| Fechar_Arquivos()}

      @ 50, 90 BUTTON btn_imprimir caption [&Imprimir] action {|| fImprimir()} WIDTH 120 TOOLTIP [Selecione] BOLD
      on key escape action {|| thiswindow.release}

   End window
   main.center
   main.activate
Return (Nil)

Function Criar_Arquivos()
   Local n 

   If !File([teste.dbf])
      DBCreate([teste], {{[Codigo], [C], 13, 0}, {[Produto], [C], 40, 0},  {[Estoque], [N], 4, 0}, {[Valor], [N], 7, 2}})
      use teste

      For n:= 1 To 13
         teste->(DbAppend())
         teste->Codigo := str(n, 13)
         teste->Produto:= [Produto ] + ltrim(str(n))
         teste->Estoque:= 1
         teste->Valor  := n
      Next
   Else
      use teste
   Endif
Return (Nil)

Procedure Fechar_Arquivos()
   Close DataBases
   AEval(Directory([*.ntx]), {|file| Ferase( file[1])})
Return (Nil)

Procedure fImprimir()
   Local aDados:= {}, aHEtiquetas:= {} , lPrimeiro:= .T., j:= y:= 0, cPrinter:= GetPrinter()

   If Empty(cPrinter)
      MsgStop([Impressora não Selecionada!], [Erro])
      Return (Nil)
   EndIf

   If [ELGIN] $ UPPER(cPrinter)
      Do while teste->(!Eof())
         For y:= 1 to teste->estoque
             aadd(aDados, {[], [], [], []})
             aDados[len(aDados), 1]:= teste->Codigo
             aDados[len(aDados), 2]:= teste->Produto
             aDados[len(aDados), 3]:= [R$ ] + transf(teste->valor, [@EB 9,999.99])
         Next
         teste->(dbskip())
      Enddo

      If !Empty(aDados)
         aHEtiquetas:= array(2, 3) /// COORDENADA X

         *** etiqueta a ESQUERDA
         aHEtiquetas[1, 1]:= aHEtiquetas[1, 2]:= aHEtiquetas[1, 3]:= [00] 
 
         *** etiqueta a DIREITA
         aHEtiquetas[2, 1]:= aHEtiquetas[2, 2]:= aHEtiquetas[2, 3]:= [200] 

         y:= 1
         ferase([COD_BARRA.TXT])
         Setalternate([COD_BARRA.TXT])
  
         For j:= 1 to Len(aDados)
             If y == 1 .or. lPrimeiro
                ? "N"
                ? "D9"
                ? "S3"
                ? "JF"
                ? "ZT"
                ? "Q240,24"      // Medidas da etiqueta (Altura 30 mm * 8 dots = 240, Distância entre etiquetas 3 mm * 8 = 24)
                ? "q320"         // Medidas da etiqueta (Largura 40 mm * 8 = 320)
                lPrimeiro:= .F.
             Endif

             ? 'A' + aHEtiquetas[y, 1] + ',30,0,2,1,1,N,"' + aDados[j, 2] + '"'      // primeira linha da descrição
             ? 'A' + aHEtiquetas[y, 2] + ',70,0,2,1,1,N,"' + aDados[j, 3] + '"'      // preço
             ? 'B' + aHEtiquetas[y, 3] + ',110,0,1,1,2,80,B,"' + aDados[j, 1] + '"'  // código de barras ean 128

             y++
             If y > 2
                ? "P1" // Quantidade de cópias
                ? "N"  // Este comando apaga a imagem buffer antes de construir uma nova imagem.
                y:= 1
             Endif
         Next
         If y > 1
            ? "P1" // Quantidade de cópias
            ? "N"  // Este comando apaga a imagem buffer antes de construir uma nova imagem.
         Endif

         Setalternate()
         WIN_PrintFileRaw(cPrinter, [COD_BARRA.TXT], [BARRA])
      Endif
   Else
      MsgStop([Não é a Impressora Correta.], [Erro])
      Return (Nil)
   Endif
Return (Nil)

Procedure Setalternate(cParam)
   If cParam == Nil
      Set Cons on
      Set Alter to
      Set Alter off
   Else
      Set cons off
      Set Alter to &cParam
      Set Alter on
   Endif
Return (Nil)

[Ladinilson Sousa]

Olá!
Usando o ByLabel imprime em arquivo e vê como é, se PPLA ou PPLB.
Eu desenhava a etiqueta usando o software da argox, imprimo em arquivo, pego o modelo e modifico o TXT, para não perder tempo."

Itamar tens um exemplo e qual software da Argox usavas?

preciso fazer uma etiqueta para transportadora.

podes mandar para mim através do email ladinilson@hotmail.com