Los mantenedores de Harbour dejan el proyecto.

por **MSDN** » 09 Jan 2020 11:58

Outra questão que nenhum projeto pago do mundo xBase está fazendo, é ter opção para WEB e MOBILE, algo que realmente funcione e não as gambiarras de sempre ! Em pleno 2020, ter o sistema rodando em um PC, em uma rede local é excelente claro, mas as coisas evoluíram...

por **Kapiaba** » 09 Jan 2020 13:55

Concordo plenamente Marcelo. Eu acho que eles não implementam, talvez, pelo alto custo, e talvez, o retorno financeiro não seja muito atrativo. Eu acho... Não tenho certeza.

Outra Marcelo: Olhe o Nome que deram para este "novo" produto: mod_harbour

http://forums.fivetechsupport.com/viewforum.php?f=45

Fala sério... Não entendi bulhufas e não tem uma única linha explicando o que é, para que é... Simplesmente "jogaram" no ar... Nem dei atenção... Deixa amadurecer, se "pegar", vai explodir exemplos, ei ai, eu olho. Abs.

por **JoséQuintas** » 09 Jan 2020 14:17

Chamou a atenção:

* Treatment of ADO Date and DateTime fields/values
XBrowse, TDataRow, TRecSet and function FWAdoStruct( oRs )

In many databases like MSAccess, MSSQL, Oracle only DateTime field type is
avaiable for storing both simple dates and date-time values. Whether a
particular field is to be treated as Date or DateTime field mostly depends
on the usage. Accordingly FWH libraries treat fields containing pure Date
values (without any time-part) as Date fields and fields containing DateTime
values are treated as DateTime fields. While this approach works satisfactorily
in most cases, there could be exceptions and the programmer needs to have
the facility to override the default behavior.

Pois é... muitos usam ADO...
Aí os usuários adoram o fivewin porque pode usar ADO... kkkk
Nem sabem que no Harbour pode usar kkkk

Ah sim... no XHarbour original talvez não dê... e o fivewin copiou do Harbour kkkk

por **Kapiaba** » 09 Jan 2020 14:49

Fivewin for xHarbour não precisa de defesa. Precisa é de quem sabe usar e abusar. kkkkkkkkkkkkkk
Usários de modo console são engraçados demais. Eu rio pra karamba. E é tão fácil aprender fivewin.

#include "fivewin.ch"
#include "xbrowse.ch"
#include "hbcompat.ch"      // required

REQUEST DBFCDX

static cMdb    := "tutor01.mdb"
static oCn

//----------------------------------------------------------------------------//

function Main()

   SET DELETED ON
   SET DATE ITALIAN
   SET CENTURY ON

   XbrNumFormat( 'A', .t. )

   ferase( cmdb )
   if .not. File( cMdb )
      FW_CreateMDB( cMdb )
   endif

   CreateTable()
   CopyFromDBF()
   BrowseTable()
   oCn:Close()

return nil

//----------------------------------------------------------------------------//

static function CreateTable()

   local cSql, c

   oCn   := FW_OpenAdoConnection( cMdb )

   TRY
      oCn:Execute( "DROP TABLE CUSTSMAL" )
   CATCH
   END

   TEXT INTO cSql
   CREATE   TABLE CUSTSMAL (
   ID       AUTOINCREMENT PRIMARY KEY,
   CUSTNAME VARCHAR( 30 ),
   MARRIED  BIT,
   AGE      BYTE,
   SALARY   MONEY
   )
   ENDTEXT

   oCn:Execute( cSql )

return nil

//----------------------------------------------------------------------------//

static function CopyFromDBF()

   local oRs

   oRs   := FW_OpenRecordSet( oCn, "CUSTSMAL" )

   USE CUSTOMER NEW ALIAS CUST SHARED READONLY VIA 'DBFCDX'

   do while ! eof() .and. RecNo() < 6

      oRs:AddNew( { "CUSTNAME", "MARRIED", "AGE", "SALARY" }, ;
                  { Left( Trim( CUST->FIRST ) + ' ' + Trim( CUST->LAST ), 30 ), ;
                    CUST->MARRIED, CUST->AGE, CUST->SALARY } )
      SKIP
   enddo

   CLOSE CUST
   oRs:Close()

return nil

//----------------------------------------------------------------------------//

static function BrowseTable()

   local oRs, oBrw, oFont, oDlg

   oRs   := FW_OpenRecordSet( oCn, "CUSTSMAL" )

   DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-14
   DEFINE DIALOG oDlg SIZE 800,400 PIXEL TITLE "ADO: SAMPLE"  FONT oFont
   @ 30,10 XBROWSE oBrw SIZE -10,-10 PIXEL OF oDlg DATASOURCE oRs ;
      AUTOCOLS AUTOSORT ;
      PICTURES "999", nil, nil, "99", "9,999,999.99" ;
      CELL LINES NOBORDER FASTEDIT

   WITH OBJECT oBrw
      :nEditTypes    := EDIT_GET
      :nStretchCol   := STRETCHCOL_WIDEST
      :Married:SetCheck()
      //
      :bKeyDown      := { |nKey| If( nKey == VK_DELETE, DeleteRow( oBrw ), ;
                                 If( nKey == VK_INSERT, AddEditDlg( oBrw ), nil ) ) }
      //
      :CreateFromcode()
   END

   @ 10, 10 BUTTON "Add"    SIZE 40,12 PIXEL OF oDlg ACTION AddEditDlg( oBrw, .t. )
   @ 10, 55 BUTTON "Edit"   SIZE 40,12 PIXEL OF oDlg ACTION AddEditDlg( oBrw )
   @ 10,100 BUTTON "Delete" SIZE 40,12 PIXEL OF oDlg ACTION DeleteRow( oBrw )

   ACTIVATE DIALOG oDlg CENTERED
   RELEASE FONT oFont
   oRs:Close()

return nil

//----------------------------------------------------------------------------//

static function AddEditDlg( oBrw, lAdd )

   local oRs         := oBrw:oRs
   local aFldNames   := { "CUSTNAME", "MARRIED", "AGE", "SALARY" }
   local aVals
   local oDlg, oFont, nRow, lOK := .f.

   DEFAULT lAdd   := ( oBrw:nLen == 0 )

   if lAdd
      aVals   := { Space( 30 ), .f., 0, 0.00 }
   else
      aVals   := oRs:GetRows( 1, 0, aFldNames )[ 1 ]
      oRs:MovePrevious() // IMPORTANT: After Get Rows we need to go back
   endif

   DEFINE FONT oFont NAME "TAHOMA" SIZE 0,-14
   DEFINE DIALOG oDlg SIZE 420,210 PIXEL FONT oFont ;
      TITLE If( lAdd, "ADD NEW CUSTOMER", "EDIT CUSTOMER" )
   nRow           := 10
   @ nRow+1, 10 SAY "Customer Name : " SIZE 60,10 PIXEL OF oDlg RIGHT
   @ nRow,   75 GET aVals[ 1 ] SIZE 115,12 PIXEL OF oDlg VALID ! Empty( aVals[ 1 ] )
   nRow  += 14
   @ nRow+1, 10 SAY "Married : " SIZE 60,10 PIXEL OF oDlg RIGHT
   @ nRow, 75 CHECKBOX aVals[ 2 ] PROMPT "" SIZE 12,12 PIXEL OF oDlg
   nRow  += 14
   @ nRow+1, 10 SAY "Age : " SIZE 60,10 PIXEL OF oDlg RIGHT
   @ nRow,   75 GET aVals[ 3 ] PICTURE "99" SIZE 30,12 PIXEL OF oDlg RIGHT ;
         VALID aVals[ 3 ] > 0

   nRow  += 14
   @ nRow+1, 10 SAY "Salary : " SIZE 60,10 PIXEL OF oDlg RIGHT
   @ nRow,   75 GET aVals[ 4 ] PICTURE "9,999,999.99" SIZE 70,12 PIXEL ;
      OF oDlg RIGHT VALID aVals[ 4 ] > 0
   nRow  += 30

   @ nRow, 115 BUTTON "Cancel" SIZE 40,12 PIXEL OF oDlg CANCEL ACTION ( lOK := .f., oDlg:End() )
   @ nRow, 160 BUTTON "OK"     SIZE 40,12 PIXEL OF oDlg ACTION ( lOK := .t., oDlg:End() )

   ACTIVATE DIALOG oDlg CENTERED

   if lOK
      aVals[ 1 ]    := AllTrim( aVals[ 1 ] )
      TRY
         if lAdd
            oRs:AddNew( aFldNames, aVals )
         else
            oRs:Update( aFldNames, aVals )
         endif
         oBrw:Refresh()
      CATCH
         oRs:CancelUpdate()
         MsgAlert( "Error writing" )
      END
      oBrw:SetFocus()
   endif

return lOk

//----------------------------------------------------------------------------//

static function DeleteRow( oBrw )

   local oRs   := oBrw:oRs
   local nPos

   if !( oRs:Eof .or. oRs:Bof )
      nPos     := oRs:AbsolutePosition
      oRs:Delete()
      oRs:AbsolutePosition := Max( 1, Min( nPos, oRs:RecordCount() ) )
      oBrw:Refresh()
   endif
   oBrw:SetFocus()

return nil

//----------------------------------------------------------------------------//

Mister Quintas, desculpe minhas brincadeiras, respeito suas opiniões... Mesmo não concordando com elas.

Abs.

por **JoséQuintas** » 09 Jan 2020 15:20

Legal.
Vou testar algumas coisas que vi nesse fonte.

por **sygecom** » 09 Jan 2020 18:42

Para mim que uso xHarbour e Hwgui, sinto falta de duas coisas.
1-No xHarbour rodar com MT(Mult theread), hoje tenho contornado com .EXE separado sistema que não é ruim e, até tenho .EXE que roda como serviço no servidor dos clientes.

2-Na HWGUI me falta ribbon bar( https://en.wikipedia.org/wiki/Ribbon_(computing) ) Já tenho algo em TESTE mas que depende de uma DLL OCX que precisa ser registrada e, ai comece outros problemas.

De resto, faço tudo aqui !

por **JoséQuintas** » 09 Jan 2020 18:46

sygecom escreveu:1-No xHarbour rodar com MT(Mult theread), hoje tenho contornado com .EXE separado sistema que não é ruim e, até tenho .EXE que roda como serviço no servidor dos clientes.

Pra não precisar EXE separado, pode usar algo simples:

PROCEDURE Main
PARAMETERS x

IF x = "SEGUNDOEXE"
   RotinaSegundoExe()
   QUIT
ENDIF

Pode até inventar parâmetros de validação, pro usuário não tentar fazer sozinho alguma coisa.

por **sygecom** » 11 Jan 2020 10:41

Esqueci de mencionar.

3-Envio de e-mail com TLS que tive que fazer com Lazarus, mas acredito que o Harbour tem isso.
4-Consumo de protocolo RTSP, esse nem com Harbour consegui fazer funcionar.

Se lembrar de mais coloco..kkkkk

por **Kapiaba** » 13 Jan 2020 09:38

Leonardo, realmente. Impossível enviar email via Outlook.com, pelo meno com xHarbour, não consegui. Se eu estivesse na Itália, conseguiria, já que lá, a porta 25 está ativa. Aqui o gobierno de mierda desligou a porta 25 e pela outras portas não vai. Eu o Enrico Maria Giordano, tentamos de todas formas e nada. Se bem que posso enviar via outros provedores. O outlook.com não nos afeta em nada. Abs.

por **JoséQuintas** » 13 Jan 2020 11:06

Kapiaba escreveu:Se eu estivesse na Itália, conseguiria, já que lá, a porta 25 está ativa. Aqui o gobierno de mierda desligou a porta 25 e pela outras portas não vai

Caracas, o anúncio sobre sair da porta 25 foi há mais de 10 anos.
Não há porque reclamar mais sobre isso.
Alguns sites continuaram aceitando depois da data estipulada, mas nem deveriam.
Só mudou a porta: é ir lá na configuração e alterar o 25 pela porta nova.

Nem sei que diferença faz pra segurança só alterar o número.

por **JoséQuintas** » 13 Jan 2020 11:14

Até dei uma procurada janeiro/2010.
Falar disso em 2020.... 10 anos depois.... vixe....

Nota: salvei no backup em abril/2010, e no git em 2015.

por **Kapiaba** » 13 Jan 2020 14:13

Exato mister Quintas. Na Itália funciona com a porta 25, com xHarbour. Aqui, não funciona em porta nenhuma o live.com / outlook.com. Não é um problema, pois usamos o provedor ACHE PERTO, e nosso enviador de emails funciona à perfeição com o provedor ACHE PERTO(hospedado no gmail). Funciona muito bem com gmail.com y yahoo.com y uol.com.br y terra.com.br. Ficamos tranquilos quanto a isso. Abs.

por **JoséQuintas** » 13 Jan 2020 15:05

Aqui NÃO instalei opcionais do Harbour, por isso gmail não funciona.
Mas o terra.com.br uso 24 horas, pela rotina de email padrão do Harbour, da hbtip.
Está usando a porta correta? se não me engano 587.

por **Kapiaba** » 13 Jan 2020 16:33

Aqui usamos CDO - RMAIL.PRG, Não funciona com nenhuma porta se for para live.com/outlook.com é alguma coisa no xHarbour que impede(TLS?). Não tem importância, pois a clientela usa os provedores: Ache Perto, uol, terra, gmail ou yahoo, com estes tudo funfa as mil maravilhas e com todas as instruções for windows(com desenho) para configurar os provedores(servidores).

Abs.

por **Kapiaba** » 15 Jan 2020 16:02

Mod_Harbour forums:

https://forum.mod-harbour.org/viewforum.php?f=22&sid=290efffae07fd4e0d2d4f25ff5ca77fd

Abs.

Quem está online