Clipper On Line • Ver Tópico - Como faço para inserir botões de atalho?

Como faço para inserir botões de atalho?

Discussão sobre a biblioteca Fivewin - O Clipper para Windows.

Moderador: Moderadores

 

Como faço para inserir botões de atalho?

Mensagempor Daiane » 31 Jul 2015 11:42

Como posso colocar botões de atalho no meu sistema
assim como está ilustrado nesse print em anexo ??
Anexos
botãoAtalho.jpg - Visualizador de Fotos do Windows.png
XHb 1.2.1 + FW 12.05 + Pelles C IDE
"Eu adoraria mudar o mundo, mas não me deram o código-fonte."
Avatar de usuário

Daiane
Usuário Nível 3

Usuário Nível 3
 
Mensagens: 122
Data de registro: 28 Out 2014 15:19
Cidade/Estado: Feira de Santana - BA
Curtiu: 27 vezes
Mens.Curtidas: 13 vezes

Como faço para inserir botões de atalho?

Mensagempor Kapiaba » 31 Jul 2015 16:21

// We are going to build a PullDown menu and we are going to assign it
// to our main Window

// This example is the typical way of start building a FiveWin program

#include "FiveWin.ch"

static oWnd

//----------------------------------------------------------------------------//

function Main()

   local oIco, oBar, oBmp

   DEFINE ICON oIco FILE "..\icons\fax.ico"

   DEFINE WINDOW oWnd FROM 1, 1 TO 22, 75 ;
      TITLE "FiveWin sample" ;
      MENU  BuildMenu() ;
      COLOR "B/W" ;
      ICON oIco

   DEFINE BUTTONBAR oBar _3D SIZE 26, 27 OF oWnd

   DEFINE BUTTON OF oBar FILENAME "..\bitmaps\16x16\new.bmp" FLAT ;
      ACTION MsgInfo( "New" ) ;
      TOOLTIP "Creates a new document"

   DEFINE BUTTON OF oBar FILENAME "..\bitmaps\16x16\open.bmp" FLAT ;
      ACTION MsgInfo( cGetFile( "*.*", "Select a document to open" ) ) ;
      TOOLTIP "Opens a document" WHEN .f.

   DEFINE BUTTON OF oBar FILENAME "..\bitmaps\16x16\floppy.bmp" FLAT ;
      ACTION MsgInfo( Time() ) TOOLTIP "Saves this document"

   DEFINE BUTTON OF oBar FILENAME "..\bitmaps\16x16\printer.bmp" FLAT ;
      ACTION MsgInfo( "Prints this document" ) TOOLTIP "Print this document" GROUP

   DEFINE BUTTON OF oBar FILENAME "..\bitmaps\16x16\prop.bmp" FLAT ;
      ACTION PrinterSetup() TOOLTIP "Setup the printer"

   DEFINE BUTTON OF oBar FILENAME "..\bitmaps\16x16\HelpInd.bmp" FLAT ;
      ACTION MsgInfo( Version() ) TOOLTIP "A multiple lines" + ;
      Chr( 13 ) + Chr( 10 ) + "tooltip!" GROUP

   DEFINE BUTTON OF oBar FILENAME "..\bitmaps\16x16\Help.bmp" FLAT ;
      ACTION MsgInfo( "fivewin power!" ) TOOLTIP "fivewin power!"

   DEFINE BUTTON OF oBar FILENAME "..\bitmaps\16x16\Exit.bmp" FLAT ;
      ACTION oWnd:End() TOOLTIP "Exit this app" GROUP

   DEFINE MESSAGE OF oWnd ;
      PROMPT FWVERSION + " " + FWCOPYRIGHT ;
      NOINSET CENTERED KEYBOARD DATE CLOCK

   DEFINE BITMAP oBmp FILENAME "..\bitmaps\fiveback.bmp"

   oWnd:bPainted = { | hDC | BmpTiled( hDC, oWnd, oBmp ) }

   ACTIVATE WINDOW oWnd ;
      VALID MsgYesNo( "Do you want to quit ?" )

return nil

//----------------------------------------------------------------------------//

function BuildMenu()

   local oMenu

   MENU oMenu
      MENUITEM "Information"
      MENU
         MENUITEM "&About..." ;
            ACTION MsgInfo( FWDESCRIPTION ) ;
            FILENAME "..\bitmaps\16x16\info.bmp"
         SEPARATOR
         MENUITEM "&End..."  ;
            ACTION oWnd:End() FILENAME "..\bitmaps\16x16\exit.bmp"

      ENDMENU

      MENUITEM "&Clients"
      MENU
         MENUITEM "&New..." ;
            ACTION ( MsgStop( "New Clients" ),;
                     oWnd:Say( 5, 5, "New Clients...", "GR+/G" ) ) ;
            FILENAME "..\bitmaps\16x16\faces.bmp"

         MENUITEM "&Modify..."  ACTION MsgInfo( "Modif. Clients" ) ;
            FILENAME "..\bitmaps\edit.bmp"

         MENUITEM "&Delete..."  ACTION MsgAlert( "Del Clients" ) ;
            FILENAME "..\bitmaps\16x16\delete.bmp"

         SEPARATOR

         MENUITEM "&Browse..."  ACTION MsgInfo( "Browse Clients" ) ;
            FILENAME "..\bitmaps\16x16\browse.bmp"

      ENDMENU

      MENUITEM "&Utilities"
      MENU
         MENUITEM "&Calculator..." ACTION WinExec( "Calc" ) ;
            FILENAME "..\bitmaps\16x16\calc.bmp"

         MENUITEM "&Internet..." ;
            ACTION WinExec( "start iexplore www.fivetech.com", 0 ) ;
            FILENAME "..\bitmaps\16x16\explorer.bmp"
      ENDMENU
   ENDMENU

return oMenu

//----------------------------------------------------------------------------//

STATIC FUNCTION BmpTiled( hDC, oWnd, oBmp )

   local nWidth := oWnd:nWidth(), nHeight := oWnd:nHeight()
   local nRow := 0, nCol := 0, n
   local nBmpWidth  := oBmp:nWidth(),  nBmpHeight := oBmp:nHeight()

   if oBmp:hBitmap == 0
      return nil
   endif

   while nRow < nHeight
      nCol = 0
      while nCol < nWidth
         PalBmpDraw( hDC, nRow, nCol, oBmp:hBitmap )
         nCol += nBmpWidth
      end
      nRow += nBmpHeight
   end

return nil

//----------------------------------------------------------------------------//


Kapiaba
Colaborador

Colaborador
 
Mensagens: 1433
Data de registro: 07 Dez 2012 15:14
Cidade/Estado: São Paulo
Curtiu: 277 vezes
Mens.Curtidas: 87 vezes

Como faço para inserir botões de atalho?

Mensagempor Kapiaba » 31 Jul 2015 16:34

Usando Recursos e PROMPT nos botoes

#Include "Fivewin.Ch"  

ANNOUNCE RDDSYS
REQUEST DBFCDX, DBFFPT

REQUEST OrdKeyNo, OrdKeyCount, OrdCreate, OrdKeyGoto

REQUEST HB_LANG_PT
REQUEST HB_CODEPAGE_PT850

FUNCTION Main()

    IF ISEXERUNNING( CFILENAME( HB_ARGV( 0 ) ) )
       __Quit()
    ENDIF

    RDDSETDEFAULT( "DBFCDX" )     // CARREGA RDD DEFINIDO NO CASO, *.CDX
    SET CENTURY ON                // 4 DIGITOS PARA O ANO
    SET DATE BRITISH              // FORMATO DD/MM/AAAA
    SET EPOCH TO YEAR( DATE() ) - 30
    SET SOFTSEEK OFF              // PARA REALIZAR UMA BUSCA APROXIMADA
    SET WRAP ON                   //-Set( 35, "ON" ) // PARA MENUS
    SETCANCEL( .F. )              // INUTILIZA ALT + C PARA ABORTAR PROGRAMA
    SET CONFIRM OFF               // CURSOR NAO PODE DESLOCAR-SE AUTOMATICAMENTE
    SET DELETED ON                // ON IMPEDIR VER REGISTROS MARCADOS PARA APAGAR
    SET ESCAPE ON                 // TECLA ESC LIGADA, POSSO ESCAPAR.
    SET EXCLUSIVE OFF             // REDE NETUSE LIGADA
    SET MULTIPLE OFF              // PROGRAMA EM REDE
    SET OPTIMIZE     ON
    SET FIXED        ON

    SET( _SET_DIRCASE,  1 )
    SET( _SET_FILECASE, 1 )

    // SetDialogEsc( .F. )  // DESLIGA O ESC NO DIALOGO
    SetBalloon( .T. ) // Balloon shape required for tooltips

    SkinButtons()     // Botoes Coloridos nas novas versoes

    SetGetColorFocus( CLR_MENTA )  // EM VENDAS.CH

    tGet():lDisColors  := FALSE
    tGet():nClrTextDis := CLR_BLUE
    tGet():nClrPaneDis := CLR_SOFTYELLOW

    HB_LANGSELECT("PT")
    HB_SETCODEPAGE( "PT850" )

    // "Exibindo a barra de tarefas"
    ShowWindow(FindWindow( 'Shell_TrayWnd',Nil), SW_SHOWNA)

    bGrad := { | lInvert | If( lInvert, ;
             { { 1/2, nRGB( 219, 230, 244 ), nRGB( 207-50, 221-25, 255 ) }, ;
             { 1/2, nRGB( 201-50, 217-25, 255 ), nRGB( 231, 242, 255 ) }  ;
             }, ;
             { { 1/2, nRGB( 219, 230, 244 ), nRGB( 207-50, 221-25, 255 ) }, ;
             { 1/2, nRGB( 201-50, 217-25, 255 ), nRGB( 231, 242, 255 ) }  ;
             } ) }

    nClr  := GetSysColor( CLR_WINDOW ) // COR DO WINDOWS DEFINIDA ANTES

    cTitle    := ( "| Vendas |"+xVersao+"| " +                               ;
                               + XFANTASIA + "|" )

    //-----------------------------------------------------------------------//
    DEFINE BRUSH oBrush    RESOURCE "LOGO2" //-> PEGA A BITMAP DO ARQUIVO.RES(LOGO.BMP)

    * Objetos de estilo
    DEFINE FONT oFnt      NAME "Ms Sans Serif"   SIZE 0, -10 BOLD
    DEFINE FONT oFont     NAME 'TAHOMA'          SIZE 0, -10 BOLD

    DEFINE CURSOR oHand RESOURCE "Dedo"

    // Direto do Diretorio
    DEFINE ICON oIco NAME "CASA"

    DEFINE WINDOW oWndMain                                                   ;
           TITLE cTitle                                                      ;
           MENU BuildMenu()                                                  ;
           BRUSH oBrush  ICON oIco  COLORS CLR_BLACK, nClr  MENUINFO 4       ;
           BORDER SINGLE MDI

    oWndMain:SetFont( oFont )        // Clipper Puro

    DEFINE BUTTONBAR OBAR BUTTONSIZE 49, 55 _3DLOOK  TOP  OF oWndMain ;
           CURSOR oHand 2007  // ESTA EM C:\SAMPLES\TESTGRAD.PRG

    // Liga o Cursor do Dedo, Mesmo Que eu Tire de ButtonBar...
    AEval( oBar:aControls, { | o | o:oCursor := oHand } )
    AEval( oBar:aControls, { | oBtn | oBtn:lBarBtn := .F. } )

    // Tratamentos Para a Barra de Botoes
    oBar:bRClicked := { || ( Click(), FUNDOWND( 1 ) ) } // Mouse Direito
    oBar:bLClicked := { || ( Click(), Logo()        ) } // Mouse Esquerdo

    oBar:SetColor( CLR_BLACK, CLR_WINDOW )

    // Este modelo e melhor esta em: \samples\testbtb.prg e testgrad.prg
    oBar:bClrGrad := { | lInvert | If( lInvert, ;
        { { 1/3, nRGB( 255, 253, 222 ), nRGB( 255, 231, 151 ) }, ;
          { 2/3, nRGB( 255, 215,  84 ), nRGB( 255, 233, 162 ) }  ;
        }, ;
          { { 1/2, nRGB( 219, 230, 244 ), nRGB( 207-50, 221-25, 255 ) }, ;
          { 1/2, nRGB( 201-50, 217-25, 255 ), nRGB( 231, 242, 255 ) }  ;
        } ) }

    // Cor no Prompt dos Botoes
    oBar:nClrText = CLR_HBLUE

    oBar:Adjust()

    oBar:ctooltip := ( OemToAnsi( "<Click> Na Barra de Ferramentas " +CRLF+  ;
                                  "Com o BotÆo  Direito do Mouse,  " +CRLF+  ;
                                  "Para Trocar o Fundo da Janela,  " +CRLF+  ;
                                  "Somente de um Arquivo BitMap... " +CRLF+  ;
                                  "<Click>  no BotÆo Esquerdo Para " +CRLF+  ;
                                  "Mostrar um Logo do Sistema...   " ) )

    //-------------Barra dos Botoes-----------------------------------------//

    IF ALLTRIM( XTIPOEMP ) = [IMOBILIARIA]

        //DEFINE BUTTON oBtnCliente OF OBAR RESOURCE "SCULLY"            ;
        DEFINE BUTTON oBtnCliente OF OBAR RESOURCE "CASA2"             ;
               MESSAGE "Inclusão dos Clientes nos Bancos de Dados"     ;
               ACTION ( Click(), oBtnCliente:Toggle(), CLIEIMOB(),     ;
                                 oBtnCliente:GoUp() )                  ;
               TOOLTIP "Manutenção dos Clientes-Use <Alt+A>"           ;
               NOBORDER GROUP BOTTOM                            ;
               MENU MENU_CLIENTES_IMOBILIARIA() WHEN( XCADASTCLIEN )

        DEFINE BUTTON OF OBAR RESOURCE "FOLDER2"                       ;
               MESSAGE "Fazer Ficha Cadastral do Imovel-Imobiliária"   ;
               ACTION ( Click(), IMOVEIS() )                           ;
               TOOLTIP "Cadastro da Ficha dos Imóveis"                 ;
               NOBORDER GROUP BOTTOM                                   ;
               MENU MENU_IMOVEIS_IMOBILIARIA()

        DEFINE BUTTON OF OBAR RESOURCE "FERRARI"                           ;
               MESSAGE "Fazer Ficha Cadastral do Proprietário-Imobiliária" ;
               ACTION( Click(), PROPRIETARIOS() )                          ;
               TOOLTIP "Cadastro da Ficha dos Proprietários"               ;
               NOBORDER GROUP BOTTOM

    ELSEIF ALLTRIM( XTIPOEMP ) = [PIZZARIA]     .OR. ;
           ALLTRIM( XTIPOEMP ) = [RESTAURANTE]  .OR. ;
           ALLTRIM( XTIPOEMP ) = [PETSHOP]      .OR. ;
           ALLTRIM( XTIPOEMP ) = [ROTISSERIE]   .OR. ;
           ALLTRIM( XTIPOEMP ) = [LOCADORA]     .OR. ;
           ALLTRIM( XTIPOEMP ) = [ELETRONICA]   .OR. ;
           ALLTRIM( XTIPOEMP ) = [PADARIA]      .OR. ;
           ALLTRIM( XTIPOEMP ) = [SUPERMERCADO] .OR. ;
           ALLTRIM( XTIPOEMP ) = [BANCA DE JORNAL]

        /* // novo modelo de menu no botao fwh1105
        MENU oServices POPUP
           MENUITEM "&Arrancar"  ACTION MENU_CLIENTES()
           MENUITEM "&Parar"     //ACTION Stop()
           MENUITEM "&Reiniciar" //ACTION ReStart()
        ENDMENU

        DEFINE BUTTON oBtnCliente OF oBar ACTION oBtn:ShowPopup()  ;
               RESOURCE "CASA2" PROMPT "Clientes" GROUP            ;
               MENU oServices                                      ;
               MESSAGE "Inclusão dos Clientes nos Bancos de Dados" ;
               TOOLTIP "Manutenção dos Clientes-Use <Alt+A>"
        */

        DEFINE BUTTON oBtnCliente OF OBAR RESOURCE "CASA2" PROMPT "Clientes" ;
               MESSAGE "Inclusão dos Clientes nos Bancos de Dados"           ;
               ACTION ( Click(), oBtnCliente:Toggle(), CLIENTES(),           ;
                                 oBtnCliente:GoUp() )                        ;
               TOOLTIP "Manutenção dos Clientes-Use <Alt+A>"                 ;
               NOBORDER GROUP BOTTOM WHEN( XCADASTCLIEN )                    ;
               MENU MENU_CLIENTES()

        IF ALLTRIM( XTIPOEMP ) = [LOCADORA]

           DEFINE BUTTON oBtnEstoque OF OBAR RESOURCE "FILMADORA"     ;
                  PROMPT "Filmes"                                     ;
                  MESSAGE "Cadastro de Filmes nos Bancos de Dados"    ;
                  ACTION( Click(), TITULO() )                         ;
                  TOOLTIP "Manutenção do Cadastro de Filmes"          ;
                  NOBORDER GROUP BOTTOM WHEN( XNOVOPRODUT )

        ENDIF

    ELSEIF ALLTRIM( XTIPOEMP ) = [PRODUTORA]

        DEFINE BUTTON oBtnCliente OF OBAR RESOURCE "SCULLY"            ;
               MESSAGE "Inclusão dos Clientes nos Bancos de Dados"     ;
               ACTION ( Click(), oBtnCliente:Toggle(), CLIENTES(),     ;
                                 oBtnCliente:GoUp() )                  ;
               TOOLTIP "Manutenção dos Clientes-Use <Alt+A>"           ;
               NOBORDER GROUP BOTTOM WHEN( XCADASTCLIEN )

    ENDIF

    IF ALLTRIM( XTIPOEMP ) != [ESTACIONAMENTO]

       DEFINE BUTTON oBtnForneced OF OBAR RESOURCE "FORNECE" PROMPT "Fornec" ;
              MESSAGE "Inclusão dos Fornecedores "                    ;
              ACTION  ( Click(), CADFORNE() )                         ;
              TOOLTIP "Manutenção dos Fornecedores "                  ;
              NOBORDER GROUP BOTTOM WHEN( XPERMISSA33 )

    ENDIF

    //-> Se NÆo For Imobiliária nem Estacionamento nem Locadora
    IF ALLTRIM( XTIPOEMP ) != [IMOBILIARIA]    .AND.                         ;
       ALLTRIM( XTIPOEMP ) != [ESTACIONAMENTO]

        IF ALLTRIM( XTIPOEMP ) != [LOCADORA]

           DEFINE BUTTON oBtnEstoque OF OBAR RESOURCE "PEPSI" PROMPT "Estoque";
                  MESSAGE "Inclusão dos Produtos No Estoque"                 ;
                  ACTION ( Click(), ESTOQUE() )                              ;
                  TOOLTIP "Manutenção dos Produtos No Estoque"               ;
                  NOBORDER GROUP BOTTOM                                             ;
                  MENU MENU_ESTOQUE() WHEN( XNOVOPRODUT )

        ENDIF

        //-> Somente para locadora
        IF ALLTRIM( XTIPOEMP ) = [LOCADORA]

            DEFINE BUTTON OF OBAR RESOURCE "CAIXA3" PROMPT "Loca"          ;
                   MESSAGE "Locação de Filmes "                            ;
                   ACTION ( Click(), LOCACAO( DeOndeVem := [LOCACAO] ) )   ;
                   TOOLTIP "Locação de Filmes "                            ;
                   NOBORDER GROUP BOTTOM

            DEFINE BUTTON OF OBAR RESOURCE "DEVOLUCAO" PROMPT "Devoluc"    ;
                   MESSAGE "Devolução de Filmes "                          ;
                   ACTION ( Click(), LOCACAO( DeOndeVem := [DEVOLUCAO] ) ) ;
                   TOOLTIP "Devolução de Filmes "                          ;
                   NOBORDER GROUP BOTTOM

            DEFINE BUTTON OF OBAR RESOURCE "BACKUP2" PROMPT "Reserv"       ;
                   MESSAGE "Reservas de Filmes Para os Clientes "          ;
                   ACTION ( Click(), RESERVAS() )                          ;
                   TOOLTIP "Reservar Filmes Para os Clientes "             ;
                   NOBORDER GROUP BOTTOM

        ENDIF

    ENDIF

    IF ALLTRIM( XTIPOEMP ) = [PIZZARIA]

        DEFINE BUTTON oBtnVendas OF OBAR RESOURCE "PIZZA10" PROMPT "Vendas";
               MESSAGE OEMTOANSI( "¸ Bem Vindo a Tela de Vendas: "   +     ;
                                  "Vendas no BalcÆo.             " )       ;
               TOOLTIP OEMTOANSI( "¸ Bem Vindo a Tela de Vendas: "   +     ;
                                  "Vendas no BalcÆo.             " )       ;
               ACTION( ( Click(), DELIVERY() ) )                           ;
               NOBORDER GROUP BOTTOM WHEN( XVENDACLIEN )

        DEFINE BUTTON oBtnVenda2 OF OBAR RESOURCE "PIZZA22" PROMPT "Mesas" ;
               MESSAGE OEMTOANSI( "¸ Bem Vindo a Tela de Vendas: "   +     ;
                                  "Vendas na Mesa.               " )       ;
               TOOLTIP OEMTOANSI( "¸ Bem Vindo a Tela de Vendas: "   +     ;
                                  "Vendas na Mesa.               " )       ;
               ACTION( ( Click(), VENDMESA() ) )                           ;
               NOBORDER GROUP BOTTOM WHEN( XVENDACLIEN )

    ELSEIF ALLTRIM( XTIPOEMP ) = [PETSHOP]      .OR. ;
           ALLTRIM( XTIPOEMP ) = [ROTISSERIE]   .OR. ;
           ALLTRIM( XTIPOEMP ) = [RESTAURANTE]  .OR. ;
           ALLTRIM( XTIPOEMP ) = [PADARIA]      .OR. ;
           ALLTRIM( XTIPOEMP ) = [SUPERMERCADO] .OR. ;
           ALLTRIM( XTIPOEMP ) = [BANCA DE JORNAL]

        IF ALLTRIM( XTIPOEMP ) = [PETSHOP]

           DEFINE BUTTON oBtnAnimal  OF OBAR RESOURCE "ANIMAIS"              ;
                  MESSAGE "Manutenção dos Animais"                           ;
                  ACTION ( Click(), ANIMAIS() )                              ;
                  TOOLTIP "Manutenção dos Animais"                           ;
                  NOBORDER GROUP BOTTOM /* WHEN( XCADASTCLIEN )                 ;
                  MENU MENU_ANIMAIS() */  // CRIAR MENU

        ENDIF

        DEFINE BUTTON oBtnVendas OF OBAR RESOURCE "VENDAS2" PROMPT "Vendas";
               MESSAGE OEMTOANSI( "¸ Bem Vindo a Tela de Vendas: "   +     ;
                                  "Vendas no BalcÆo. Alt+V       " )       ;
               TOOLTIP OEMTOANSI( "¸ Bem Vindo a Tela de Vendas: "   +     ;
                                  "Vendas no BalcÆo. Alt+V       " )       ;
               ACTION( ( Click(), TELAVEND() ) ) ;
               NOBORDER GROUP BOTTOM WHEN( XVENDACLIEN )

        IF ALLTRIM( XTIPOEMP ) = [ROTISSERIE]  .OR. ;
           ALLTRIM( XTIPOEMP ) = [RESTAURANTE] .OR. ;
           ALLTRIM( XTIPOEMP ) = [PADARIA]

            DEFINE BUTTON oBtnVendas  OF OBAR RESOURCE "PIZZA22" PROMPT "Mesas";
                   MESSAGE OEMTOANSI( "¸ Bem Vindo a Tela de Vendas: "   +     ;
                                      "Vendas na Mesa.               " )       ;
                   TOOLTIP OEMTOANSI( "¸ Bem Vindo a Tela de Vendas: "   +     ;
                                      "Vendas na Mesa.               " )       ;
                   ACTION( ( Click(), VENDMESA() ) )                           ;
                   NOBORDER GROUP BOTTOM WHEN( XVENDACLIEN )

        ENDIF

    ENDIF

    IF ALLTRIM( XTIPOEMP ) = [PRODUTORA]

        DEFINE BUTTON OF OBAR RESOURCE "FILMADORA"                         ;
               MESSAGE ( OemToAnsi( "Lan‡amentos de Fitas Para os "  ) ) + ;
                       ( OemToAnsi( "Clientes(Produtora de V¡deos) " ) ) + ;
                       ( OemToAnsi( "Use as Teclas de Fun‡Æo SHIFT+F2" ) ) ;
               ACTION ( Click() ), INCFITAS()                              ;
               TOOLTIP ( OemToAnsi( "InclusÆo de Fitas Para Clientes" ) )+ ;
                                                                    CRLF + ;
                       ( OemToAnsi( "(Produtora)-Click na Seta Acima" ) )+ ;
                                                                    CRLF + ;
                       ( OemToAnsi( "Para Ver Sub-Menu de Op‡äes.   " ) )  ;
               NOBORDER GROUP BOTTOM                                                      ;
               MENU MENUFITAS()

        DEFINE BUTTON OF OBAR RESOURCE "PRINTER"                             ;
               MESSAGE "Lançamentos de Orçamentos Para os Clientes" +        ;
                       "(Folha Tamanho Normal-Discriminado Por Número)"  /*  ;
               ACTION ( Click(), ORCA_NUM() )                                ;
               TOOLTIP "Lançamentos de Orçamentos/Pedidos Para os Clientes " ;
                                                                      +CRLF+ ;
                       "( Discriminado Por Número-Folha Tamanho Normal )"    ;
               NOBORDER GROUP BOTTOM                */

        DEFINE BUTTON OF OBAR RESOURCE "VENDAS2"            ;
               MESSAGE "Lançamento de Cupom Fiscal" +       ;
                       "(Orçamentos/Pedidos em Ticket's)" + ;
                       "( Discriminado Por Número " +       ;
                       "Tipo Supermercado )" /*             ;
               ACTION ( Click(), ORCACOND() )               ;
               TOOLTIP "Lançamento de Cupom Fiscal" +CRLF+  ;
                       "(Orçamentos/Pedidos em Ticket's)"   ;
                                                    +CRLF+  ;
                       "( Discriminado Por Número "      +  ;
                       "Tipo Supermercado )"                ;
               NOBORDER GROUP BOTTOM
                                           */

    ENDIF

    IF ALLTRIM( XTIPOEMP ) = [ESTACIONAMENTO]

        DEFINE BUTTON oBtnCliente OF OBAR RESOURCE "SCULLY"                  ;
               MESSAGE "Inclusão dos Clientes nos Bancos de Dados"           ;
               ACTION ( Click(), oBtnCliente:Toggle(), CLIESTAC(),           ;
                                 oBtnCliente:GoUp() )                        ;
               TOOLTIP "Manutenção dos Clientes-Use <Alt+A>"                 ;
               NOBORDER GROUP BOTTOM                                            ;
               MENU MENU_CLIENTES_ESTACIONAMENTO() WHEN( XCADASTCLIEN )

        DEFINE BUTTON OF OBAR RESOURCE "XP_CHAVE"                            ;
               MESSAGE "Inclusão dos Veiculos nos Bancos de Dados"           ;
               ACTION( Click(), VEICULOS() )                                 ;
               TOOLTIP "Inclusão de Veículos "                               ;
               NOBORDER GROUP BOTTOM

        DEFINE BUTTON OF OBAR RESOURCE "XP_COMANDA"                          ;
               MESSAGE "Inclusão dos Serviços nos Bancos de Dados"           ;
               ACTION( Click(), SERVICOS() )                                 ;
               TOOLTIP "Manutenção dos Serviços do Estacionamento"           ;
               NOBORDER GROUP BOTTOM

        DEFINE BUTTON OF OBAR RESOURCE "FUNCION"                             ;
               MESSAGE "Inclusão dos Funcionarios nos Bancos de Dados"       ;
               ACTION( Click(), FUNCIONA() )                                 ;
               TOOLTIP "Manutenção dos Funcionários"                         ;
               NOBORDER GROUP BOTTOM

        DEFINE BUTTON OF OBAR RESOURCE "FERRARI"                             ;
               MESSAGE  "Entrada de Veículos"                                ;
               TOOLTIP  "Entrada de Veículos no Estacionamento"              ;
               NOBORDER GROUP BOTTOM

        DEFINE BUTTON OF OBAR RESOURCE "FERRARI2"                            ;
               MESSAGE  "Saida de Veículos"                                  ;
               TOOLTIP  "Saida de Veículos do Estacionamento"                ;
               NOBORDER GROUP BOTTOM

    ENDIF

    //-> Area do Contas a Pagar e Receber

    //-> Contas a Pagar
    DEFINE BUTTON oBtnBaixaPag OF OBAR RESOURCE "PAGAR" PROMPT "Pagar"       ;
           MESSAGE "Manutenção das Contas a Pagar Para os Fornecedores"      ;
           TOOLTIP "Manutenção das Contas a Pagar Para os Fornecedores"      ;
           NOBORDER GROUP BOTTOM                                                ;
           ACTION( ( Click(), BAIXATIT( DeOndeVem := 2 ) ) )                 ;
           MENU MENUCONTASAPAGAR() WHEN( XALTTITULOS )

    //-> Contas a Receber oBtnBaixaPag, oBtnBaixaRec
    DEFINE BUTTON oBtnBaixaRec OF OBAR RESOURCE "BANCOS"  PROMPT "Receb"     ;
           MESSAGE "Manutenção dos Títulos em Aberto(Baixar Títulos) dos " + ;
                   "Clientes - Contas a Receber"                             ;
           TOOLTIP "Manutenção dos Títulos em Aberto(Baixar Títulos) dos " + ;
                   "Clientes - Contas a Receber"                             ;
           NOBORDER GROUP BOTTOM                                                ;
           ACTION( ( Click(), BAIXATIT( DeOndeVem := 1 ) ) )                 ;
           MENU MENUCONTASARECEBER() WHEN( XALTTITULOS )

    DEFINE BUTTON oBtnConfSist OF OBAR RESOURCE "USUARIOS" PROMPT "Acessos"  ;
           MESSAGE "Configurações Gerais do Sistema "                        ;
           TOOLTIP "Configurações Gerais do Sistema "                        ;
           ACTION( ( Click(), OPERADOR() ) )                                 ;
           NOBORDER GROUP BOTTOM                                                ;
           MENU MENU_CONFIGURA_SISTEMA()                                     ;
           WHEN( XCONFSISTEMA )

    IF ALLTRIM( XTIPOEMP ) != [LOCADORA]

       DEFINE BUTTON OF OBAR RESOURCE "CALCULATOR" PROMPT "Calc"             ;
              MESSAGE OEMTOANSI( "¸ Calculadora do Windows" +                ;
                                 "Tecla de Fun‡Æo: Ctrl+<F10>" )             ;
              ACTION ( Click(), SET_CALC() )                                 ;
              TOOLTIP OEMTOANSI( "¸ Calculadora do Windows" +CRLF+           ;
                                 "Tecla de Fun‡Æo: Ctrl+<F10>" )             ;
              NOBORDER GROUP BOTTOM

    ENDIF

    IF ALLTRIM( XTIPOEMP ) = [LOCADORA]

       MENU oPopup POPUP 2007
          MENUITEM "Calculadora"                              ;
              RESOURCE  "CALC16X16"                           ;
              ACTION ( Click(), SET_CALC() )                  ;
              MESSAGE "¸ Calculadora do Windows"

          SEPARATOR   
          MENUITEM "Calendario Grande"                        ;
              RESOURCE  "CALEND"                              ;
              ACTION( ( Click(), CALEND() ) )                 ;
              MESSAGE "¸ Calendário For Windows"

          SEPARATOR   
          MENUITEM "Calendario Pequeno"                       ;
              RESOURCE  "CALEND"                              ;
              ACTION( ( Click(), FwCalendar() ) )             ;
              MESSAGE "¸ Calendário For Windows Pequeno" // By Manuel Mercado

       ENDMENU

       DEFINE BUTTON oBtnCalend OF oBar ACTION oBtnCalend:ShowPopup()           ;
              RESOURCE "XP_CALEND" PROMPT "Calend" GROUP BOTTOM                    ;
              MENU oPopup TOOLTIP OemToAnsi( "¸ Calend rios For Windows  "+CRLF+;
                                             "Tecla de Fun‡Æo: <Ctrl+F11>"+CRLF+;
                                             "Tecla de Fun‡Æo: <Ctrl+F12>" )
    ELSE

       DEFINE BUTTON OF OBAR RESOURCE "XP_CALEND" PROMPT "Calend"                              ;
              MESSAGE OEMTOANSI( "¸ Calend rios For Windows:-> " +           ;
                                 "Teclas de Fun‡Æo: Ctrl+<F11> " +           ;
                                 "e <Ctrl+<F12>                " )           ;
              TOOLTIP OEMTOANSI( "¸ Calend rios For Windows... " + CRLF +    ;
                                 "Tecla de Fun‡Æo: <Ctrl+F11>  " + CRLF +    ;
                                 "Tecla de Fun‡Æo: <Ctrl+F12>  " )           ;
              ACTION( ( Click(), CALEND() ) )                                ;
              NOBORDER GROUP BOTTOM

    ENDIF

    DEFINE BUTTON oBackup OF OBAR RESOURCE "BACKUP" PROMPT "Backup"          ;
           MESSAGE "Este Programa Gerará Automaticamente, um Backup " +      ;
                   "de Segurança."                                           ;
           ACTION( ( Click(), XBLITE() ) )                                   ;
           NOBORDER GROUP BOTTOM

    //----------------------------------------------------------------------//

    oBackup:cToolTip := ( "Este Programa Gerará Automaticamente, um   "+CRLF+;
                          "Backup de Segurança das Cópias de Todos    "+CRLF+;
                          "os Seus Arquivos.                          "+CRLF+;
                          "Se Você Está Trabalhando em Rede de        "+CRLF+;
                          "Computadores é Muito Recomendável, que     "+CRLF+;
                          "Você Feche Todos os Programas em Todos     "+CRLF+;
                          "os  Outros Computadores, Antes de Começar. "+CRLF+;
                          "Evite Perdas Desnecessárias. Cuidado!!!    "+CRLF+;
                          "Se For de Sua Preferência, Use o WinZip.Exe"+CRLF+;
                          "ou PkZip.Exe ou BraZip.Exe  Para Gerar Suas"+CRLF+;
                          "Cópias.  O Importante, é  Que  Você,  Nunca"+CRLF+;
                          "Esqueça de Fazer Seus Backup's Diariamente!"+CRLF+;
                          "                                           " )
    oBackup:lToolTipBallon   := .T.
    oBackup:nTooltipWidth    := 250
    oBackup:nTooltipTexColor := nRGB( 000, 000, 000 )
    oBackup:nTooltipBKColor  := nRGB( 250, 250, 250 )
    oBackup:cTooltipTitle    := OemToAnsi( "Sistema de Backup do Sistema" )
    oBackup:nTooltipIcon     := 1  && 0=NONE / 1=TTI_INFO / 2=TTI_WARNING / 3=TTI_ERROR
    //-> 0=TTDT_AUTOMATIC / 1=TTDT_RESHOW / 2=TTDT_AUTOPOP / 3=TTDT_INITIAL
    oBackup:nSetDelayType    := 2
    oBackup:nSetDelayTime    := 32767  //-> Velocidade do TOOLTIP-> +- 1:30 Secs

    //----------------------------------------------------------------------//

    //-> ESTA EM \SAMPLES\TESTGRAD.PRG tem que vir antes do botao
    /*
    MENU oPopup POPUP
       MENUITEM "One" ACTION MsgInfo( 1 )
       MENUITEM "Two" ACTION MsgInfo( 2 )
    ENDMENU
    */
    DEFINE BUTTON oBtnIndexar OF OBAR RESOURCE "ORGANIZAR" PROMPT "Indexar"  ;
           MESSAGE "Reorganizar(Indexar) Bancos de Dados"                    ;
           ACTION ( ( Click(), REINDEXA() ) )                                ;
           TOOLTIP "Reorganizar(Indexar) Bancos de Dados"                    ;
           NOBORDER GROUP BOTTOM        WHEN( XINDEXARBAN )

    DEFINE BUTTON oSaida OF OBAR RESOURCE "SAIDA", "SAIR2" PROMPT "Saida"    ;
           MESSAGE "Saida do Programa"                                       ;
           TOOLTIP "Saida do Programa-Use <Alt+S>"                           ;
           ACTION( ( Click(), oSaida:Toggle(), TERMINAR(), oSaida:GoUp() ) ) ;
           NOBORDER GROUP BOTTOM


    WndCenter( oWndMain:hWnd )

    @ 61.50, 0  GIF oGif FILE ".\LAGO.GIF" SIZE 230, 100 ADJUST

    IF IsWinNT() .OR. IsWin2000()  // Para Windows XP/NT e 2000 / 2003
        ACTIVATE WINDOW OWNDMAIN MAXIMIZED                                    ;
                 ON INIT ( SetMenuBG( oWndMain,, oBrush ),                    ;
                           oTmr   := FlashWndTimer( oWndMain,,                ;
                 { | | IsIconic( oWndMain:hWnd ) }, CHECA_RESOLUCAO(),        ;
                                                    DLGINICIAL(), TIRA_X(),   ;
                                                    ONSTART( OWNDMAIN ),      ;
                                                 oBtnCliente:SetFocus() ) )   ;
                 VALID( TERMINAR() )                                          ;
                 ON PAINT ( DbCommitAll() )

     ELSE // Windows At‚ o Millenium Edition - 09/08/2005 - JoÆo Santos
        ACTIVATE WINDOW OWNDMAIN MAXIMIZED                                    ;
                 ON INIT ( SetMenuBG( oWndMain, CLR_LGREEN ),                 ;
                           oTmr   := FlashWndTimer( oWndMain,,                ;
                 { | | IsIconic( oWndMain:hWnd ) }, CHECA_RESOLUCAO(),        ;
                                                    DLGINICIAL(), TIRA_X(),   ;
                                                    ONSTART( OWNDMAIN ) ) )   ;
                 VALID( TERMINAR() )                                          ;
                 ON PAINT ( DbCommitAll() )

    ENDIF

RETURN NIL


Kapiaba
Colaborador

Colaborador
 
Mensagens: 1433
Data de registro: 07 Dez 2012 15:14
Cidade/Estado: São Paulo
Curtiu: 277 vezes
Mens.Curtidas: 87 vezes

Como faço para inserir botões de atalho?

Mensagempor Kapiaba » 31 Jul 2015 16:47

Você também pode usar um editor de BITMAPS, tipo o IRFANVIEW.EXE e criar os seus botões como .BMP e incorporar ao seu ARQUIVO DE RECURSOS .RES OU .RC com o WORKSHOP.EXE ou PELLESC.EXE. E chama no seu menu principal, conforme exemplo acima.

Imagem

Abs
Kapiaba
Colaborador

Colaborador
 
Mensagens: 1433
Data de registro: 07 Dez 2012 15:14
Cidade/Estado: São Paulo
Curtiu: 277 vezes
Mens.Curtidas: 87 vezes

Como faço para inserir botões de atalho?

Mensagempor Daiane » 03 Ago 2015 11:54

Pelo que entendi essa parte aqui que faz o botão atalho né isso?
DEFINE BUTTONBAR oBar _3D SIZE 26, 27 OF oWnd
   
   DEFINE BUTTON OF oBar FILENAME "..\bitmaps\16x16\new.bmp" FLAT ;
   ACTION MsgInfo( "New" ) ;
   TOOLTIP "Creates a new document"


no caso eu tenho q desenhar no pelles os botões?
não entendi muito bem o código fonte
XHb 1.2.1 + FW 12.05 + Pelles C IDE
"Eu adoraria mudar o mundo, mas não me deram o código-fonte."
Avatar de usuário

Daiane
Usuário Nível 3

Usuário Nível 3
 
Mensagens: 122
Data de registro: 28 Out 2014 15:19
Cidade/Estado: Feira de Santana - BA
Curtiu: 27 vezes
Mens.Curtidas: 13 vezes

Como faço para inserir botões de atalho?

Mensagempor rochinha » 11 Ago 2015 10:46

Amiguinhos,

O comando DEFINE WINDOW irá desenhar a janela propriamente dita.

O comando DEFINE BUTTONBAR, o nome já diz tudo, BARra de botões, será o contâiner dos botões que virão depois.

Para ligar o buttonbar na window voce usou OF WINDOW(...OF oWnd...), então ao ligar os botões à buttonbar você colocará OF BUTTONBAR(...OF OBar...)
OPS! LINK QUEBRADO? Veja ESTE TOPICO antes e caso não encontre ENVIE seu email com link do tópico para fivolution@hotmail.com. Agradecido.

@braços : ? )

A justiça divina tarda mas não falha, enquanto que a justiça dos homens falha porque tarda.
Avatar de usuário

rochinha
Membro Master

Membro Master
 
Mensagens: 4139
Data de registro: 18 Ago 2003 20:43
Cidade/Estado: São Paulo - Brasil
Curtiu: 454 vezes
Mens.Curtidas: 175 vezes

Como faço para inserir botões de atalho?

Mensagempor Daiane » 16 Mar 2016 09:12

Olá gnt,
Kapiaba,estou tentando fazer da segunda maneira que vc postou
porem dar um erro
Estou fazendo dessa forma:

DEFINE CURSOR oHand
DEFINE BUTTONBAR OBAR BUTTONSIZE 30, 31 _3DLOOK TOP OF oWnd ;
CURSOR oHand 2007


So que quando passo o ponteiro do mouse no atalho o ele some
como faço para enquanto eu tiver passando o ponteiro do mouse no atalho ele não desaparecer?

ele so aparece depois q tiro o ponteiro do atalho
XHb 1.2.1 + FW 12.05 + Pelles C IDE
"Eu adoraria mudar o mundo, mas não me deram o código-fonte."
Avatar de usuário

Daiane
Usuário Nível 3

Usuário Nível 3
 
Mensagens: 122
Data de registro: 28 Out 2014 15:19
Cidade/Estado: Feira de Santana - BA
Curtiu: 27 vezes
Mens.Curtidas: 13 vezes

Como faço para inserir botões de atalho?

Mensagempor Daiane » 17 Mar 2016 09:25

Consegui resolver simplemente usando HAND depois do oHand

então ficou assim:

DEFINE CURSOR oHand HAND
DEFINE BUTTONBAR OBAR BUTTONSIZE 63, 31 _3DLOOK TOP OF oWnd ;
CURSOR oHand 2007
XHb 1.2.1 + FW 12.05 + Pelles C IDE
"Eu adoraria mudar o mundo, mas não me deram o código-fonte."
Avatar de usuário

Daiane
Usuário Nível 3

Usuário Nível 3
 
Mensagens: 122
Data de registro: 28 Out 2014 15:19
Cidade/Estado: Feira de Santana - BA
Curtiu: 27 vezes
Mens.Curtidas: 13 vezes

Como faço para inserir botões de atalho?

Mensagempor Daiane » 30 Jun 2016 08:51

Alguem sabe dizer como faz pra colocar a descrição no botão de atalho?

a maneiro q to criando os botões:
DEFINE CURSOR oHand HAND
DEFINE BUTTONBAR OBAR BUTTONSIZE 68, 25 _3DLOOK TOP OF oWnd ; //72
CURSOR oHand 2007

DEFINE BUTTON OF oBar RESOURCE "#7103";
ACTION MFOLDIR(oWnd);
TOOLTIP "Mudar Empresa" NOBORDER GROUP BOTTOM
XHb 1.2.1 + FW 12.05 + Pelles C IDE
"Eu adoraria mudar o mundo, mas não me deram o código-fonte."
Avatar de usuário

Daiane
Usuário Nível 3

Usuário Nível 3
 
Mensagens: 122
Data de registro: 28 Out 2014 15:19
Cidade/Estado: Feira de Santana - BA
Curtiu: 27 vezes
Mens.Curtidas: 13 vezes

Como faço para inserir botões de atalho?

Mensagempor Daiane » 30 Jun 2016 09:30

Resolvido.
É so usar o PROMPT
XHb 1.2.1 + FW 12.05 + Pelles C IDE
"Eu adoraria mudar o mundo, mas não me deram o código-fonte."
Avatar de usuário

Daiane
Usuário Nível 3

Usuário Nível 3
 
Mensagens: 122
Data de registro: 28 Out 2014 15:19
Cidade/Estado: Feira de Santana - BA
Curtiu: 27 vezes
Mens.Curtidas: 13 vezes




Retornar para FiveWin

Quem está online

Usuários vendo este fórum: Nenhum usuário registrado online e 2 visitantes


Faça uma doação para o forum
v
Olá visitante, seja bem-vindo ao Fórum Clipper On Line!
Efetue o seu login ou faça o seu Registro