Função WIN_OSNETREGOK()

por **Kapiaba** » 03 Jun 2014 16:36

Função WIN_OSNETREGOK()

Senhores boa tarde, porfa, alguém tem esta função completa para FiveWin for xHarbour, e em qualquer versão do windows e que possa disponibiliar?

Link:

viewtopic.php?f=4&t=11325

Obg. abs. :xau

por **toya** » 04 Jun 2014 22:21

Apenas ajustei para resolver a questão da OS_ISUSERANADMIN()

//------------------------------------------------------------------------------

//Ajustado para xHarbour. Por favor tirem suas conclusões.

#include "common.ch"
#include "directry.ch"

#define WIN_HKEY_LOCAL_MACHINE 0 
#define WIN_HKEY_CLASSES_ROOT 1 
#define WIN_HKEY_CURRENT_USER 2 
#define WIN_HKEY_CURRENT_CONFIG 3 
#define WIN_HKEY_LOCAL_MACHINE 4 
#define WIN_HKEY_USERS 5 

/* NOTE: To change any of these registry settings
         Administrator rights are required by default in Windows. [vszakats] */

FUNCTION WIN_OSNETREGOK( lSetIt, lDoVista )
   LOCAL bRetVal := .T.
   LOCAL cKeySrv
   LOCAL cKeyWks

   IF ! ISLOGICAL( lSetIt )
      lSetIt := .F.
   ENDIF
   IF ! ISLOGICAL( lDoVista )
      lDoVista := .T.
   ENDIF

   IF ! lDoVista .AND. Os_IsWinVISTA() //win_osIsVistaOrUpper()
      /* do nothing */
   ELSEIF Os_IsWin9X() // hb_osIsWin9x()
      bRetVal := QueryRegistry( WIN_HKEY_LOCAL_MACHINE, "System\CurrentControlSet\Services\VxD\VREDIR", "DiscardCacheOnOpen", 1, lSetIt )
   ELSE
      cKeySrv := "System\CurrentControlSet\Services\LanmanServer\Parameters"
      cKeyWks := "System\CurrentControlSet\Services\LanmanWorkStation\Parameters"

      IF lSetIt
         lSetIt := ! Os_IsWinNT() .OR. os_IsUserAnAdmin() //wapi_IsUserAnAdmin() // #toya: 04/06/2014 - 20:59:01 - #Release 001.zzz
      ENDIF

      /* Server settings */
      bRetVal := bRetVal .AND. QueryRegistry( WIN_HKEY_LOCAL_MACHINE, cKeySrv, "CachedOpenLimit", 0, lSetIt )
      bRetVal := bRetVal .AND. QueryRegistry( WIN_HKEY_LOCAL_MACHINE, cKeySrv, "EnableOpLocks", 0, lSetIt ) /* Q124916 */
      bRetVal := bRetVal .AND. QueryRegistry( WIN_HKEY_LOCAL_MACHINE, cKeySrv, "EnableOpLockForceClose", 1, lSetIt )
      bRetVal := bRetVal .AND. QueryRegistry( WIN_HKEY_LOCAL_MACHINE, cKeySrv, "SharingViolationDelay", 0, lSetIt )
      bRetVal := bRetVal .AND. QueryRegistry( WIN_HKEY_LOCAL_MACHINE, cKeySrv, "SharingViolationRetries", 0, lSetIt )

      IF Os_IsWinVISTA() // win_osIsVistaOrUpper()
         /* If SMB2 is enabled turning off oplocks does not work, so SMB2 is required to be turned off on Server. */
         bRetVal := bRetVal .AND. QueryRegistry( WIN_HKEY_LOCAL_MACHINE, cKeySrv, "SMB2", 0, lSetIt )
      ENDIF

      /* Workstation settings */
      bRetVal := bRetVal .AND. QueryRegistry( WIN_HKEY_LOCAL_MACHINE, cKeyWks, "UseOpportunisticLocking", 0, lSetIt )
      bRetVal := bRetVal .AND. QueryRegistry( WIN_HKEY_LOCAL_MACHINE, cKeyWks, "EnableOpLocks", 0, lSetIt )
      bRetVal := bRetVal .AND. QueryRegistry( WIN_HKEY_LOCAL_MACHINE, cKeyWks, "EnableOpLockForceClose", 1, lSetIt )
      bRetVal := bRetVal .AND. QueryRegistry( WIN_HKEY_LOCAL_MACHINE, cKeyWks, "UtilizeNtCaching", 0, lSetIt )
      bRetVal := bRetVal .AND. QueryRegistry( WIN_HKEY_LOCAL_MACHINE, cKeyWks, "UseLockReadUnlock", 0, lSetIt )

      IF Os_IsWinVISTA() //win_osIsVistaOrUpper()
         bRetVal := bRetVal .AND. QueryRegistry( WIN_HKEY_LOCAL_MACHINE, cKeyWks, "FileInfoCacheLifetime", 0, lSetIt )
         bRetVal := bRetVal .AND. QueryRegistry( WIN_HKEY_LOCAL_MACHINE, cKeyWks, "FileNotFoundCacheLifetime", 0, lSetIt )
         bRetVal := bRetVal .AND. QueryRegistry( WIN_HKEY_LOCAL_MACHINE, cKeyWks, "DirectoryCacheLifetime", 0, lSetIt )
      ENDIF

      IF Os_IsWinNT() //hb_osIsWin2K()
         bRetVal := bRetVal .AND. QueryRegistry( WIN_HKEY_LOCAL_MACHINE, "System\CurrentControlSet\Services\MRXSmb\Parameters", "OpLocksDisabled", 1, lSetIt )
      ENDIF
   ENDIF

   RETURN bRetVal

FUNCTION WIN_OSNETVREDIROK( /* @ */ nResult )
   LOCAL aFiles

   nResult := 0

   IF Os_IsWin9X() // hb_osIsWin9x()
      aFiles := Directory( GetEnv( "WINDIR", "C:\WINDOWS" ) + "\SYSTEM\VREDIR.VXD" )  /* Check for faulty files. */
      IF ! Empty( aFiles )
         IF aFiles[ 1 ][ F_SIZE ] == 156749 .AND. aFiles[ 1 ][ F_TIME ] == "11:11:10"
            nResult := 1111
         ELSEIF aFiles[ 1 ][ F_SIZE ] == 140343 .AND. aFiles[ 1 ][ F_TIME ] == "09:50:00"
            nResult := 950
         ENDIF
      ENDIF
   ENDIF

   RETURN Empty( nResult )

//------------------------------------------------------------------------------
// #toya: 04/06/2014 - 21:17:26 - #Release 001.zzz

#pragma BEGINDUMP

#include <windows.h>
#include "hbapiitm.h"

HB_FUNC( OS_ISUSERANADMIN ) 
{
  BOOL iResult = FALSE ;
  typedef int (WINAPI *USERADMIN)( void );
  HINSTANCE hLib;
  USERADMIN ProcAdd;
  hLib = LoadLibrary("shell32.dll");
  if (hLib != NULL)
  {
    ProcAdd = ( USERADMIN ) GetProcAddress(hLib, "IsUserAnAdmin");
    if (NULL != ProcAdd)
    {
      iResult = (ProcAdd)() ;
    }
    FreeLibrary( hLib );
  }
  hb_retl( iResult ) ;
}

#pragma ENDDUMP

//------------------------------------------------------------------------------

Função WIN_OSNETREGOK()

Função WIN_OSNETREGOK()

Função WIN_OSNETREGOK()

Quem está online