Clipper On Line • Ver Tópico - Uso correto da função NETERR()

Uso correto da função NETERR()

Discussão sobre a linguagem CA-Clipper.

Moderador: Moderadores

 

Uso correto da função NETERR()

Mensagempor Ingrid Farabulini » 01 Abr 2018 19:03

Olá,

Estou tendo dificuldade com o uso correto da função NETERR() adicionada logo na linha seguinte ao comando USE, no caso "USE ARQ.DBF SHARED NEW". Quando tento abrir um arquivo .DBF que não existe no diretório atual, é exibida na tela a seguinte mensagem de erro "Error DBFNTX/1001 Open Error: ARQ.DBF (DOS Error 2)" com as opções "Quit, Retry, Default". Se escolho a opção "Default", a NETERR() retorna falso ".F.", mas não deveria retornar .T., por ter ocorrido um erro de abertura? Aproveito para perguntar se existe alguma maneira da mensagem de erro padrão do Clipper não ser exibida caso ocorra a tentativa de abrir um arquivo .DBF que não existe. Pensava que a mensagem padrão de erro só era exibida caso não utilizasse a função NETERR() na linha seguinte.

Só para completar, utilizo Windows XP/7 rodando Clipper 5.2e.
Obrigada, aguardo pela ajuda! :*
Ingrid Farabulini
Usuário Nível 1

Usuário Nível 1
 
Mensagens: 3
Data de registro: 24 Mar 2018 21:36
Cidade/Estado: Canasvieiras-SC
Curtiu: 0 vez
Mens.Curtidas: 0 vez

Uso correto da função NETERR()

Mensagempor Jairo Maia » 02 Abr 2018 01:50

Olá Ingrid,

Seja bem vinda ao fórum.

A função NETERR() inicia com valor .F., e será alterado apenas se for usado algum comando que necessite travar o registro ou arquivo em rede, e se manterá com o mesmo status até o uso da próxima tentativa.

Você não pode tentar abrir um aquivo que não existe. Precisa verificar duas coisas:

1 - Se o arquivo existe;
2 - Se ele já não está aberto. Exemplo:

Local x, cArquivo, cAlias, aIndices

cArquivo := "NomeArq.Dbf"                     // nome do .DBF
aIndices := { "Indice1", "Indice2", etc... }  // nomes dos indices

cAlias := Left( cArquivo, 1, At( ".", cArquivo ) - 1 )

If File( cArquivo )            // verifica se arquivo existe

If Select( cAlias ) = 0       // verifica se não está aberto

  USE ( cArquivo ) SHARED NEW  // abre o arquivo

  If Used()                    // verifica se deu tudo certo

   For x = 1 To Len( aIndices )

    SET INDEX TO ( aIndices[x] ) ADDITIVE  // abre os indices

   Next

   DbSetOrder( nOrdem )

  EndIf

Else

  DbSelect( cAlias )
  DbSetOrder( nOrdem )
 
EndIf

EndIf


Para evitar mensagens de erros no Clipper, somente alterando o arquivo ERRORSYS.PRG, mas é extremamente desaconselhável.
Abraços, Jairo
Harbour / Clipper 5.2e - Blinker 7
(Por favor, não encaminhe via mensagem privada ou e-mail, dúvidas que podem ser compartilhadas com todos no fórum)
Avatar de usuário

Jairo Maia
Colaborador

Colaborador
 
Mensagens: 2064
Data de registro: 16 Ago 2010 13:46
Cidade/Estado: Campinas-SP
Curtiu: 228 vezes
Mens.Curtidas: 203 vezes

Uso correto da função NETERR()

Mensagempor JoséQuintas » 02 Abr 2018 12:17

Só clarear o que foi postado pelo Jairo:

A mensagem de erro DOS ERROR 2 é quando o arquivo não existe.
Isso não é erro de rede, é falta de arquivo mesmo.

A opção é primeiro testar se o arquivo existe, e decidir o que fazer.

IF .NOT. File( "arquivo.dbf" )
   ? "Arquivo não existe"
   // e o que fazer se não existir
ENDIF
José M. C. Quintas
Harbour 3.4, mingw, gtwvg, multithread, dbfcdx, ADO+MySql, hbnetio, PNotepad
"The world is full of kings and queens, who blind our eyes and steal our dreams Its Heaven and Hell"
Avatar de usuário

JoséQuintas
Colaborador

Colaborador
 
Mensagens: 9419
Data de registro: 26 Fev 2007 11:59
Cidade/Estado: São Paulo-SP
Curtiu: 6 vezes
Mens.Curtidas: 548 vezes

Uso correto da função NETERR()

Mensagempor Ingrid Farabulini » 02 Abr 2018 18:51

Olá meninos, agradeço a atenção de vocês e as mensagens de boas vindas!

Agradeço a explicação sobre o uso correto da função NETERR(). Havia lido em um livro que se houvesse algum erro com os comandos USE e APPEND BLANK, essa função também acusaria. Agora tenho certeza que não! Pelo menos vou poder explicar minha dificuldade melhor agora: o que preciso é criar o arquivo caso ocorra a exclusão desse arquivo mesmo depois de testado a existência do mesmo com a função FILE(), ou seja, nesse intervalo mínimo de segundos entre a função FILE() e o comando USE. Por esse motivo, gostaria que a mensagem de erro seja ocultada, visto que o sistema só saberá se precisa criar esse arquivo a ser usado exatamente no momento que obtém acesso a ele.
USE TEMPFILE SHARED NEW    // Se TEMPFILE não existir, exibirá a mensagem de erro.
Acredito que somente com um controle de erro BEGIN/BRAKE vou conseguir corrigir, o que é desaconselhável.

Alguma sugestão?
Obrigada pela ajuda. :*
Ingrid Farabulini
Usuário Nível 1

Usuário Nível 1
 
Mensagens: 3
Data de registro: 24 Mar 2018 21:36
Cidade/Estado: Canasvieiras-SC
Curtiu: 0 vez
Mens.Curtidas: 0 vez

Uso correto da função NETERR()

Mensagempor JoséQuintas » 02 Abr 2018 20:01

Provavelmente está com uma rotina no servidor que vai apagando o arquivo conforme processa.
Vai ser quase impossível impedir problemas, se tem mais terminais envolvidos.
Se for isso, o ideal é criar um arquivo de semáforo.
Ou ir criando com extensões diferentes arquivo001, arquivo002, etc.

Lembrando que o próprio Windows tem problemas com isso, de ficar apagando/criando...
José M. C. Quintas
Harbour 3.4, mingw, gtwvg, multithread, dbfcdx, ADO+MySql, hbnetio, PNotepad
"The world is full of kings and queens, who blind our eyes and steal our dreams Its Heaven and Hell"
Avatar de usuário

JoséQuintas
Colaborador

Colaborador
 
Mensagens: 9419
Data de registro: 26 Fev 2007 11:59
Cidade/Estado: São Paulo-SP
Curtiu: 6 vezes
Mens.Curtidas: 548 vezes

Uso correto da função NETERR()

Mensagempor Jairo Maia » 02 Abr 2018 23:32

Olá Ingrid,

Ingrid Farabulini escreveu:Havia lido em um livro que se houvesse algum erro com os comandos USE e APPEND BLANK, essa função também acusaria.
E sim, acusa. Porém, no comando USE você não pode usar o parâmetro SHARED. Se você usar SHARED o arquivo não é travado. Se usar apenas o comando USE sem SHARED, o arquivo será aberto em modo exclusivo, e NETERR() será .T. Se não for possível abrir o arquivo em modo exclusivo, NETERR() então será .F.

Ingrid Farabulini escreveu:o que preciso é criar o arquivo caso ocorra a exclusão desse arquivo mesmo depois de testado a existência do mesmo com a função FILE(), ou seja, nesse intervalo mínimo de segundos entre a função FILE() e o comando USE.
Caramba, qual exatamente seria essa situação que nesses milésimos de segundo o arquivo poderia ser deletado?

Ingrid Farabulini escreveu:Acredito que somente com um controle de erro BEGIN/BRAKE vou conseguir corrigir
Mesmo com BEGIN/BREAK não seria possível sem alterar o arquivo ERRORSYS. O problema é o que fazer a partir dai. Tem como você postar um exemplo da situação que você precisa tratar?
Abraços, Jairo
Harbour / Clipper 5.2e - Blinker 7
(Por favor, não encaminhe via mensagem privada ou e-mail, dúvidas que podem ser compartilhadas com todos no fórum)
Avatar de usuário

Jairo Maia
Colaborador

Colaborador
 
Mensagens: 2064
Data de registro: 16 Ago 2010 13:46
Cidade/Estado: Campinas-SP
Curtiu: 228 vezes
Mens.Curtidas: 203 vezes

Uso correto da função NETERR()

Mensagempor JoséQuintas » 18 Abr 2018 18:50

Por coincidência acabei de pensar numa situação onde isso poderia acontecer:

Pensei em ter arquivos DBFs temporários, como resultado de pesquisas no MySQL.
Mas definir um tempo de vida útil pra eles, a fim de atualizar com novos dados do MySQL.
Seria uma situação onde poderia acontecer isso de precisar de um controle em milésimos de segundo... rs

Só um arquivo de semáforo mesmo.
Tipo cada registro com o nome do arquivo, e um RLock() ao criar/apagar, pra impedir que outro processo faça o mesmo.

Em multithread, milésimos de segundo podem fazer diferença, porque são processos rodando local na mesma máquina.

Outra opção é fazer reaproveitamento de registro deletado, assim pode excluir os registros e reaproveitar, sem que o arquivo "engorde" demais.
Mas vai precisar pensar muito bem, seja qual for a opção escolhida.
José M. C. Quintas
Harbour 3.4, mingw, gtwvg, multithread, dbfcdx, ADO+MySql, hbnetio, PNotepad
"The world is full of kings and queens, who blind our eyes and steal our dreams Its Heaven and Hell"
Avatar de usuário

JoséQuintas
Colaborador

Colaborador
 
Mensagens: 9419
Data de registro: 26 Fev 2007 11:59
Cidade/Estado: São Paulo-SP
Curtiu: 6 vezes
Mens.Curtidas: 548 vezes

Uso correto da função NETERR()

Mensagempor Gabriel Pavan » 16 Mai 2018 15:17

Boa Tarde Pessoal... Sou novo por aqui... estou meio perdido.... Utilizo clipper 5.2 com Blinker... estou transformando meu sistema em rede, e estava usando o Neterr() para todos os acessos, e sempre com o comando USE vendas EXCLUSIVE antes... porém, creio que não teria necessidade bloquear o acesso ao BD quando por exemplo for fazer somente uma pesquisa... Alguém poderia me ajudar? desde já Obrigado.
Gabriel Pavan
Usuário Nível 1

Usuário Nível 1
 
Mensagens: 1
Data de registro: 16 Mai 2018 15:09
Cidade/Estado: Jundiaí/SP
Curtiu: 0 vez
Mens.Curtidas: 0 vez

Uso correto da função NETERR()

Mensagempor vcatafesta » 16 Mai 2018 17:17

Olá Gabriel,

Veja se isso te ajuda.

Defines:
#define true                     .T.
#define false                    .F.
#define FALSO                  .F.
#define OK                     .T.
#define ESC                     27
#define P_DEF(Par, Def)    Par := if( Par = Nil, Def, Par )


Função para abrir arquivo BD:
*-----------------------------------------------*
function NetUse( cBcoDados, lModo, nSegundos, cAlias )
*-----------------------------------------------*
   LOCAL cScreen := SaveScreen()
   LOCAL nArea   := 0
   LOCAL Restart := OK
   LOCAL cStr1
   LOCAL cStr2
   LOCAL cStr3
   LOCAL cStr4
   LOCAL cStr5
   LOCAL cStr6
   LOCAL lForever
   LOCAL cTela
   LOCAL lAberto := FALSO
   P_DEF( lModo, OK )
   P_DEF( nSegundos, 2 )

   cBcoDados := StrTran( cBcoDados, '.DBF')
   cAlias    := Iif( cAlias = NIL, cBcoDados, cAlias )
   lForever     := ( nSegundos = 0 )
   lAberto    := (cBcoDados)->(Used())
   
   if lAberto  // 14:03 25/04/2018
      (cBcoDados)->(DbCloseArea())
      lAberto := false
   endif
   
   while Restart
      while (lForever .OR. nSegundos > 0)
         if lModo
            Use (cBcoDados) SHARED NEW Alias ( cAlias )
         else
            Use (cBcoDados) EXCLUSIVE NEW Alias ( cAlias )
         endif
         if !NetErr()
            ResTela( cScreen )
            return( OK )
         endif
         cTela := Mensagem("Tentando acesso a " + Upper(AllTrim(cBcoDados)) + ".DBF...")
         Inkey(.5)
         nSegundos -= .5
         ResTela( cTela )
      EndDo
      nOpcao := Conf("Acesso Negado a " + Upper(AllTrim( cBcoDados )) + " Novamente ? ")
      if nOpcao = OK
         ResTart := OK
      else
         ResTart := FALSO
         DbCloseAll()
         FChDir( oAmbiente:xBase )
         SetColor("")
         Cls
         cStr1 := "#1 Se outra estação estiver usando o sistema, finalize-a. ;;"
         cStr2 := "#2 Se outra estação estiver indexando, aguarde o término. ;;"
         cStr3 := "#3 Se SHARE estiver instalado, aumente os parãmetros de   ;"
         cStr4 := "   travamento de arquivos. Ex.: SHARE /F:18810 /L:510.    ;;"
         cStr5 := "#4 Em ambiente de rede NOVELL, verifique o arquivo NET.CFG;"
         cStr6 := "   e se necessário, acrescente a linha FILE HANDLES=127.  ;"
         Alert( cStr1 + cStr2 + cStr3 + cStr4 + cStr5 + cStr6, "W+/B")
         Break
         //Quit
      endif
   EndDo
   return( FALSO )


funções para travar arquivo, travar registro, incluir registro, e liberar:
function TravaReg( nTentativa, aRegistros )
*+-----------------------------------+*
   LOCAL cScreen := SaveScreen()
   LOCAL Restart := OK
   LOCAL lContinua
   
   hb_default(@nTentativa, 2)
   lContinua  := ( nTentativa == 0 )

   while Restart
      while (!RLock() .AND. ( nTentativa > 0 .OR. lContinua ))
         Mensagem(" Travando Registro " + AllTrim(Str( Recno())) + " no Arquivo " + Alias(), CorBox())
         if inKey(1) = K_ESC
            exit
         endif
         nTentativa--
      enddo
      if !RLock()
         if !Conf("Registro em uso. Tentar Novamente ?" )            
            ResTela( cScreen )               
            return( false )
         endif
         ResTart    := OK
         nTentativa := 2
      else
         ResTela( cScreen )
         return( true )
      endif
   EndDo

function TravaArq()
*+-----------------------------------+*
   if Flock()
      return( true )
   endif
   while !FLock()
      ErrorBeep()
      if !Conf("Arquivo em uso em outra Estaçao. Tentar Novamente ?" )
         return( false )
      endif
      if FLock()
         return( true )
      endif
   enddo
   return( true )

function Incluiu()
*+-----------------------------------+*
   DbAppend()
   if !NetErr()
      return( true )
   endif   
   while NetErr()
      ErrorBeep()
      if !Conf("Registro em uso em outra Estaçao. Tentar Novamente ?")
         return( false )
      endif
      DbAppend()
      if !NetErr()
         return( true )
      endif
   EndDo
   return( true )

function Libera()
*+-----------------------------------+*
   //DbCommit()              // Atualiza Buffers
   DbSkip(0)            // Refresh
   DbGoto( Recno())      // Refresh      
   DbUnLock()         // Libera Registros / Arquivos
   return Nil


Qualquer dúvida, é só dar um tok.

att,
Harbour, C, C++, Ruby, Python, Go, Delphi, Haskell, Html, PHP, mingw, gtwvg, multithread, dbfcdx, letodb
=================================================
Senhor, sem Ti, nada podemos fazer!
vcatafesta
Usuário Nível 1

Usuário Nível 1
 
Mensagens: 12
Data de registro: 20 Fev 2015 23:22
Cidade/Estado: Pimenta Bueno/RO
Curtiu: 2 vezes
Mens.Curtidas: 0 vez

Uso correto da função NETERR()

Mensagempor vcatafesta » 16 Mai 2018 17:32

Formas de Usar as funções:
if Printer->(TravaArq())
     for nX := 1 To nTam
        Printer->(DbAppend())
        for nField := 1 To Printer->(FCount())
           Printer->(FieldPut( nField, aPrinter[nX,nField]))
        next
     next
     Printer->(Libera())
endif


if Conf( "Pergunta: Confirma Registro da Senha ?")
   if Vendedor->(TravaReg())
        Vendedor->Senha := MsEncrypt(Upper(cPasse))
      Vendedor->(Libera())
   endif
endif


if Conf("Pergunta: Confirma Inclusao do Grupo ?")
      if Grupo( cCodigo )
         if Grupo->(Incluiu())
            Grupo->Codgrupo   := cCodigo
            Grupo->Desgrupo   := cDescricao
            Grupo->Atualizado := Date()
            Grupo->Servico    := IF( cServico = "S", OK, FALSO )
            Grupo->(Libera())
         endif
      endif
   endif


Lembre-se: 1)TravaArq() para quando necessário fazer alterações/exclusões em vários registros
2)TravaReg() quando alterações/exclusões em somente um registro.
3)Inclui() para incluir registros
4)Libera(). use sempre logo após as outras funções
Harbour, C, C++, Ruby, Python, Go, Delphi, Haskell, Html, PHP, mingw, gtwvg, multithread, dbfcdx, letodb
=================================================
Senhor, sem Ti, nada podemos fazer!
vcatafesta
Usuário Nível 1

Usuário Nível 1
 
Mensagens: 12
Data de registro: 20 Fev 2015 23:22
Cidade/Estado: Pimenta Bueno/RO
Curtiu: 2 vezes
Mens.Curtidas: 0 vez




Retornar para CA-Clipper

Quem está online

Usuários vendo este fórum: Nenhum usuário registrado online e 2 visitantes


Faça uma doação para o forum
v
Olá visitante, seja bem-vindo ao Fórum Clipper On Line!
Efetue o seu login ou faça o seu Registro